*************************************************                               
         SYSTEM   OPTIONS                                                       
*                                               *                               
*                                               *                               
*        R B M - 2   A B O R T / E X I T        *                               
*                                               *                               
*                                               *                               
*************************************************                               
         PAGE                                                                   
         SYSTEM   SIG5P                                                         
         DEF      ABEX                                                          
         DEF      PMD                                                           
         DEF      BKGSEQ                                                        
         DEF      DBKG                                                          
         DEF      ABEXEXIT                                                      
         DEF      ABEXR8X                                                       
OLAYFLAG EQU      'ABEX'                                                        
         SYSTEM   CPRMON                                                        
*                                                                               
         TITLE    '**** ABORT OVERLAY ****'                                     
*                                                                               
*                                   PROCESSES ABORT AND EXIT CAL'S FOR          
*                                     BCKG.                                     
*                                                                               
*                                                                               
ABEX     RES      0                                                             
         DO       #MAP=0                                                        
         LW,R11   Y3                                                            
         CW,R11   K:JCP1                                                        
         BANZ     ABEXEXIT          EXIT IF BKG IS CKPTED                       
         FIN      #MAP=0                                                        
         LW,R10   Y01                                                           
         LW,R11   R10                                                           
         AW,R11   Y08                                                           
         STS,R10  K:CTST            SET BKG IDLE, RESET ABEX                    
         DO1      #MAP                                                          
         CAL1,7   BKGSTOP                                                       
         LI,R11   1                                                             
         CW,R11   K:CTST                                                        
         BANZ     A02               B IF ABORT DURING PMD                       
         LI,R11   X'10000'                                                      
         CW,R11   K:CTST                                                        
         BANZ     A02               B IF 'ABORT ATT' CLEANUP                    
         LW,R0    K:CTST                                                        
         CI,R0    4                 IS THIS AN ABORT OR EXIT                    
         BANZ     EXXIT                                                         
         LI,R0    0                                                             
         STW,R0   K:LIMIT           CLEAR LIMIT ON BCKG TIME                    
         STW,R0   K:BPGLIM          RESET BKG PAGE LIMIT                        
         B        ABBORT            BTO PROCESS ABORT                           
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
*        CLEAN UP POST-EXIT STATES (DUMP OR ABORT-ATTENDED WAIT)                
*                                                                               
A02      LI,R10   0                                                             
         STS,R10  K:CTST            CLEAR FLAG JUST TESTED                      
*                                                                               
*        COMMON TO ABORT/EXIT/CLEANUP                                           
*                                                                               
A03      RES      0                                                             
         LW,R11   K:CTST                                                        
         CI,R11   1                                                             
         BANZ     PMD               B IF PMD REQUIRED                           
         MTW,0    K:PMD+4                                                       
         BNEZ     PMD               B IF KEYIN PMD REQUIRED                     
         CI,R11   X'10000'                                                      
         BANZ     WAITMSG           B IF ABORT ATT WAIT                         
         LI,R7    0                                                             
         XW,R7    K:DBTS            CLEAR THE BKG DUMP TSPACE PTR               
         BEZ      %+2               B IF ALREADY CLEAR                          
         BAL,R8   RELTEMP           RELEASE BKG DUMP TSPACE                     
         BAL,R8   FINDBKG           GET BKG TABLE INDEXES                       
         LI,R9    LMIT              LM TERMINATION BIT                          
         LI,R10   0                                                             
         LI,R11   4                                                             
         CW,R11   K:CTST                                                        
         BANZ     %+2               B IF NORMAL EXIT                            
         AI,R9    LMIA              LM ABNORMAL TERMINATION BIT                 
         AW,R11   Y01               BKG IDLE BIT                                
         STS,R10  K:CTST            RESET IDLE AND NORMAL EXIT BITS             
         STB,R10  K:PMD1            RESET TRAP ABORT INDICATOR                  
         STW,R10  K:ABTLOC          RESET ABORT TYPE CODE                       
         BAL,R8   TMLM              FORCE BACKGROUND TERMINATION                
         LW,R0    K:JCP1                                                        
         CI,R0    1                                                             
         BANZ     ABEXEXIT          B IF BKG JOB STILL DEFINED                  
         LI,R6    BKGJID                                                        
         BAL,R8   JMTERM            PERFORM BKG JOB CLEANUP                     
         LI,R7    0                                                             
         XW,R7    JCBBKG+JCBNXLM    CLEAR BKG NEXT-LM ID TSPACE PTR             
         BEZ      %+2               B IF ALREADY CLEARED                        
         BAL,R8   RELTEMP           RELEASE BKG NEXT-LM ID TSPACE               
         LI,R8    0                                                             
         LW,R9    YC                                                            
         STS,R8   K:JCP1            RESET BKG ACTIVE AND JCP EXECUTING          
         LCI      BKGIDLME-BKGIDLM                                              
         LM,R8    BKGIDLM                                                       
         CAL1,2   R8                '!!BEGIN IDLE'                              
ABEXEXIT B        CT1               EXIT FROM OVERLAY.                          
WAITMSG  RES      0                                                             
         LCI      PT%-TYPEFPT                                                   
         LM,R8    TYPEFPT                                                       
         CAL1,2   R8                TYPE BKG ABORT WAIT MSG                     
         B        ABEXEXIT                                                      
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
*        PROCESS BKG ABORT                                                      
*                                                                               
ABBORT   RES      0                                                             
         LW,R14   Y04               'SKIP TO NEXT JOB' BIT                      
         LW,R0    K:JCP1                                                        
         CI,R0    1                 JOB DEFINED                                 
         BAZ      A06               NO. BRANCH TO TERM BKG STREAM               
         LI,R1    X'80'             UNCONDITIONAL PMD                           
         STS,R1   K:JCP1            SET IT                                      
*        UNCONDITIONAL PMD TO GET ABORT PSD AND REGISTERS                       
         CI,R0    2                 IS IT AN ATTENDED RUN                       
         BAZ      A05               BRANCH IF NOT ATTENDED MODE                 
         LI,R1    X'10000'          ABORT ATT BIT                               
         STS,R1   K:CTST            SET IT                                      
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
*        COMMON TO ABORT AND NON-JCP EXIT (PROCESS DUMPS AND RELOAD JCP)        
*        R14 CONTAINS VALUE FOR SKIP-TO-NEXT-JOB FLAG                           
*                                                                               
A05      RES      0                                                             
         LW,R0    Y004              FLAG TO LOAD JCP NEXT                       
         LW,R1    Y006                                                          
         STS,R0   K:CTST                                                        
         LCI      3+#DFACNT*2                                                   
         LM,R7    JCPLMID                                                       
         STM,R7   *JCBBKG+JCBNXLM   SET JCP AS NEXT BKG LM                      
         LI,R1    X'C0'                                                         
         AND,R1   K:JCP1                                                        
         BEZ      A06               B IF NO PMD NEEDED                          
         LI,R0    0                                                             
         STS,R0   K:JCP1            RESET PMD REQUEST FLAGS                     
         LI,R1    1                                                             
         STS,R1   K:CTST            SET BIT TO EXECUTE PMD                      
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
*        COMMON TO ABORT AND ANY EXIT (SET FLAGS)                               
*                                                                               
A06      RES      0                                                             
         LW,R15   A92                                                           
         STS,R14  K:JCP1            SET/RESET BKG CONTROL FLAGS                 
         B        A03                                                           
*                                                                               
A92      DATA     X'84000200'                                                   
*                                                                               
         PAGE                                                                   
         SPACE    3                                                             
*                                   SBR TO CHANGE HEX TO BCD                    
*                                       CALL IS  BAL,R8  HEXBCD                 
*                                    WHERE                                      
*                                         R11=VALUE TO CONVERT                  
*                                    EXITS R10,R11=VALUE IN BCD                 
*                                                                               
HEXBCD   LI,R7    -28                                                           
         LI,R6    0                                                             
         LW,R9    R11                                                           
HEXBCD1  LW,R0    R9                                                            
         SLS,R0   0,R7                                                          
         AND,R0   XF                GET NEXT DIGIT                              
         AI,R0    X'F0'                                                         
         CI,R0    X'FA'                                                         
         BL       %+2               CHANGE TO BCD                               
         AI,R0    -X'39'                                                        
         STB,R0   R10,R6            STORE IT                                    
         AI,R6    1                                                             
         AI,R7    4                                                             
         BLEZ     HEXBCD1                                                       
         B        *R8               EXIT                                        
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
*        SUBROUTINE TO GET BKG TASK ID IN R4                                    
*        CAN NOT USE TMFINDT SINCE IT IGNORES TERMING TASKS                     
*                                                                               
*                                                                               
FINDBKG  RES      0                                                             
         LW,R10   BKGNAME                                                       
         LW,R11   BLANKS            BKG TASK NAME IN R10,11                     
         LB,R4    STILMID           NR OF STI ENTRIES                           
FB10     RES      0                                                             
         LW,R5    STITCB,R4         CHECK STI ENTRY                             
         BEZ      FB20              B IF NOT IN USE                             
         LB,R5    STILMID,R4        GET LOAD MODULE INDEX                       
         CD,R10   LMINAME,R5                                                    
         BNE      FB20              B IF NOT BKG LM                             
         LW,R6    LMIJID,R5                                                     
         LB,R6    R6                GET JOB INDEX                               
         CI,R6    BKGJID                                                        
         BE       *R8               B IF CORRECT JOB ID                         
FB20     RES      0                                                             
         BDR,R4   FB10              CHECK NEXT TASK ID                          
*        FALL THRU IF BKG TASK IN BKG JOB NOT FOUND                             
         LI,R0    0                                                             
         LW,R1    YC                                                            
         STS,R0   K:JCP1            SET BKG INACTIVE                            
         LI,R1    X'10001'                                                      
         STS,R0   K:CTST                                                        
         B        ABEXEXIT                                                      
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
*        PROCESS BKG EXIT                                                       
*                                                                               
EXXIT    RES      0                                                             
         LI,R14   0                 FLAG: NO SKIP TO NEXT JOB CMND              
         LW,R0    K:JCP1                                                        
         CW,R0    Y8                IS JCP EXITTING                             
         BANZ     B10               YES                                         
B06      LI,R1    X'40'                                                         
         LI,R0    0                                                             
         STS,R0   K:JCP1            CLEAR CONDITIONAL PMD BIT                   
         B        A05                                                           
B10      RES      0                                                             
         CI,R0    1                 JOB DEFINED BIT                             
         BAZ      A06               BRANCH IF FIN CMND RECEIVED                 
         LW,R0    Y002              FLAG TO LOAD NON-JCP NEXT                   
         LW,R1    Y006                                                          
         STS,R0   K:CTST                                                        
         B        A06                                                           
         PAGE                                                                   
         SPACE    3                                                             
*                                                                               
BKGSEQ   RES      0                                                             
         PUSH     5,R7                                                          
         LW,R1    Y4                BKG RUNNING BIT                             
         DISABLE                                                                
         CW,R1    K:JCP1                                                        
         BANZ     BS95              B IF BKG IS RUNNING                         
         STS,R1   K:JCP1            SET BKG RUNNING                             
         ENABLE                                                                 
         LW,R7    JCBBKG+JCBNXLM    GET BKG NEXT-LM TSPACE POINTER              
         BNEZ     BS50              B IF TSPACE IS ALREADY DEFINED              
         LI,R7    3+#DFACNT*2       SIZE NEEDED                                 
         BAL,R8   GETTEMP           GET TSPACE FOR BKG NEXT-LM ID               
         B        BS90              B IF NO TSPACE                              
         STW,R7   JCBBKG+JCBNXLM    SAVE TSPACE POINTER                         
*                                                                               
BS50     RES      0                                                             
         LCI      3+#DFACNT*2                                                   
         LM,R7    JCPLMID                                                       
         STM,R7   *JCBBKG+JCBNXLM   SET NEXT BKG LM TO JCP                      
         ENABLE                                                                 
         LW,R1    Y00C                                                          
         STS,R1   K:CTST            FLAGS: RUN BKL, LOAD JCP                    
         BAL,R11  CTRIG             TRIGGER THE CONTROL TASK                    
         AI,R8    1                 SKIP RETURN                                 
         B        BS95                                                          
*                                                                               
BS90     RES      0                 CANT GET TSPACE                             
         LI,R0    0                                                             
         LW,R1    Y4                                                            
         STS,R0   K:JCP1            RESET BKG RUNNING FLAG                      
*                                                                               
BS95     RES      0                                                             
         ENABLE                                                                 
         PULL     5,R7                                                          
*                                                                               
ABEXR8X  B        *R8                                                           
*                                                                               
         PAGE                                                                   
         SPACE    5                                                             
*                                                                               
*                                                                               
PMD      RES      0                 START BKG TO DUMP ITSELF                    
         LI,R0    1                                                             
         LW,R1    R0                                                            
         OR,R1    Y01                                                           
         STS,R0   K:CTST            RESET BKG IDLE, SET PMD                     
         BAL,R8   FINDBKG           GET BKG TABLE INDEXES                       
         LI,R6    STCBAPSD          ALT PSD INDEX IN STCB                       
         LW,R7    STITCB,R4         BKG STCB ADDRESS                            
         LW,R8    DBKGADDR                                                      
         AND,R8   X1FFFF            ADDRESS ONLY                                
         DO       #MAP                                                          
         OR,R8    Y004              MAP                                         
         FIN      #MAP                                                          
         LI,R9    0                 (R8,R9) = ALT PSD FOR BKG                   
         LI,R11   STIALT            ALT PSD DISPATCH FLAG                       
         DISABLE                                                                
         LH,R0    LMISTAT,R5        GET CURRENT STATUS                          
         CI,R0    LMIT                                                          
         BANZ     PMD21             B IF IN TERMINATION                         
         STS,R11  STIPRIO,R4        FORCE ALT PSD DISPATCH                      
         STD,R8   *R7,R6            SET ALT PSD                                 
         DO       #MAP&#ROLL                                                    
         LW,R0    STITCB,R4                                                     
         AND,R0   XSTINLW           RESET LONG WAIT BIT                         
         STW,R0   STITCB,R4                                                     
         FIN                        #MAP&#ROLL                                  
         STB,R9   STICOUNT,R4       CLEAR NON-ECB BLOCKS                        
         STH,R9   STIOVID,R4        CLEAR OLAY ID                               
*                                   ADDRESS ACCESS PRIVILEGE                    
PMD20    RES      0                                                             
         ENABLE                                                                 
         LW,R7    K:DBTS                                                        
         BNEZ     PMD21             B IF TSPACE ALREADY THERE                   
         LI,R7    64                                                            
         BAL,R8   GETTEMP           GET DUMP CONTROL BLOCK                      
*        (DONT TRUST BKG TO DO IT, AND RELEASE OK)                              
         B        DBNOTS            B IF NOT ENUF TSPACE                        
         STW,R7   K:DBTS            SAVE TSPACE POINTER                         
PMD21    RES      0                                                             
         ENABLE                                                                 
         DO       #MAP                                                          
         CAL1,7   BKGSTOP                                                       
         CAL1,7   BKGSTART                                                      
         FIN      #MAP                                                          
         B        ABEXEXIT                                                      
*                                                                               
DBKGADDR BAL,R0   DBKG              PROVIDES OMAN INTERFACE TO DBKG             
         PAGE                                                                   
*                                                                               
*        FOLLOWING CODE EXECUTED IN BKG CONTEXT                                 
*                                                                               
WXDCB    EQU      2                                                             
WXFWA    EQU      3                                                             
WXLWA    EQU      4                                                             
WXBAD    EQU      5                                                             
WXBAL    EQU      6                                                             
BXFLAGS  EQU      7*4                                                           
MVIRT    EQU      1**4                                                          
M4WD     EQU      1**6                                                          
MEBC     EQU      1**7                                                          
WXBUF    EQU      14                                                            
WXRES    EQU      54                                                            
TIMEC    EQU      X'10'             CAL CODE FOR GETTIME                        
*                                                                               
DBKG     RES      0                 SETUP FOR BACKGROUND DUMPS                  
         LCI      0                                                             
         STM,R0   *K:DBTS                                                       
*        FIND THE REGISTERS                                                     
*        IF DUMP IS BEING REENTERED, REGISTERS WILL HAVE BEEN SAVED             
*        AS THOUGH BACKGROUND TERMINATED IN A CAL                               
         LB,R4    TCBPOINT                                                      
         LB,R5    STILMID,R4        LM INDEX                                    
         LD,R6    STIRTSB,R4                                                    
         BEZ      DBKG03            B IF NOT IN A CAL                           
*        GET REGS FOR TERM WITHIN CAL                                           
         MTW,0    -1,R6                                                         
         BEZ      %+4               B IF AT HIGHEST CAL LEVEL                   
         LW,R7    0,R6              GET NEXT HIGHER STIRTSB                     
         LW,R6    -1,R6                                                         
         B        %-4                                                           
         LI,R0    0                                                             
         STW,R0   -2,R6             SET OVERLAY ID TO ZERO                      
         STD,R6   *K:RTS            SET STACK POINTER DW                        
         STD,R6   STIRTSB,R4        SET STIRTSB                                 
         B        DBKG06                                                        
*                                                                               
DBKG03   LB,R6    K:PMD1                                                        
         CI,R6    X'EE'                                                         
         BNE      DBKG04            B IF NOT A TRAP ABORT                       
*        IF NOT A TRAP ABORT, SAVED STUFF WAS IN REGS ALREADY                   
*        IF TRAP ABORT, CONTINUE                                                
         LD,R6    *PCBPOINT         (R6,7) = BKG UTS POINTER                    
         LH,R7    R7                                                            
         AND,R7   X7FFF             (R7)=SPACE COUNT                            
         CI,R7    22                                                            
         BL       DBKG04            B IF TRAP SAVE WAS IMPOSSIBLE               
*        GET TRAP SAVED REGISTERS AND PSD                                       
         AI,R6    5                                                             
         LI,R7    X'1FFFE'                                                      
         AND,R6   R7                ADDR OF SAVED REGS                          
         LW,R7    R6                                                            
         AI,R7    -2                ADDR OF SAVED PSD                           
         B        DBKG05                                                        
*                                                                               
DBKG04   RES      0                 USE REGS AND PSD FROM TERMINATION           
         LW,R6    K:DBTS            ADDRESS OF SAVED REGS                       
         LW,R7    TCBPOINT                                                      
         AI,R7    2*STCBAPSD        ADDRESS OF SAVED PSD                        
*                                                                               
DBKG05   RES      0                 SIMULATE A CAL PUSH TO SAVE                 
*        STUFF FOR A LATER DUMP                                                 
         LD,R8    LMIRTS,R5                                                     
         AND,R9   X7FFF             WORD COUNT                                  
         LCW,R9   R9                                                            
         MSP,R9   LMIRTS,R5         CLEAR STACK                                 
         LCI      8                                                             
         LM,R8    *R6                                                           
         PSM,R8   LMIRTS,R5         PUSH FIRST 8 REGS                           
         AI,R6    8                                                             
         LCI      8                                                             
         LM,R8    *R6                                                           
         PSM,R8   LMIRTS,R5         PUSH LAST 8 REGS                            
         LD,R8    *R7               GET PSD                                     
         LI,R10   0                 NO OLAY ID                                  
         LI,R11   0                 NO SAVED STIRTSB                            
         LI,R12   0                                                             
         LCI      5                                                             
         PSM,R8   LMIRTS,R5         PUSH THE REST                               
         LD,R8    LMIRTS,R5                                                     
         STD,R8   STIRTSB,R4        SET NEW STIRTSB                             
DBKG06   RES      0                                                             
         LW,R7    K:DBTS            GET DUMP BKG TEMP SPACE ADDR                
         AND,R7   XFFFFFF           ADDRESS ONLY                                
         LW,R5    R7                                                            
         AI,R5    WXRES-1                                                       
         LI,R4    5                                                             
         LW,R3    DODCB-1,R4        COPY THE DCB                                
         STW,R3   *R5,R4                                                        
         BDR,R4   %-2                                                           
         AI,R5    1                                                             
         STW,R5   WXDCB,R7          SET DCB POINTER                             
         AI,R5    WXBUF-WXRES-1     SET UP HEADER                               
         LI,R4    32                                                            
         LW,R3    BLANKS                                                        
         STW,R3   *R5,R4            BLANK THE BUFFER                            
         BDR,R4   %-1                                                           
         LI,R4    DBKGHE-DBKGH                                                  
         LW,R3    DBKGH-1,R4                                                    
         STW,R3   *R5,R4                                                        
         BDR,R4   %-2               COPY HEADER INTO BUFFER                     
         LD,R2    BKGTIME                                                       
         LW,R4    K:ABTLOC                                                      
         CI,R4    -1                                                            
         BE       DBKG07            B IF TIMEOUT                                
         BG       %+3               B IF NOT PAGE LIMIT                         
         LD,R2    BKGPLIM                                                       
         B        DBKG07                                                        
         LD,R2    BKGABT                                                        
         LW,R4    K:CTST                                                        
         CI,R4    4                                                             
         BAZ      DBKG07            B IF ANY OTHER ABORT                        
         LD,R2    BKGEXIT           NORMAL EXIT                                 
DBKG07   RES      0                                                             
         LCI      2                                                             
         STM,R2   DBKGHTYP-DBKGH+1,R5   SET TYPE OF TERMINATION                 
         LB,R4    TCBPOINT                                                      
         LD,R2    STIRTSB,R4                                                    
         LW,R10   -4,R2             GET SAVED PSD                               
         LW,R11   -3,R2                                                         
         LW,R1    R7                SAVE R7                                     
         LW,R2    R10               SAVE R10                                    
         BAL,R8   HEXBCD            CONVERT PSD WORD 1                          
         LD,R12   R10               SAVE CONVERTED WORD                         
         LW,R11   R2                                                            
         BAL,R8   HEXBCD            CONVERT PSD WORD 0                          
         LW,R7    R1                RESTORE R7                                  
         LCI      4                                                             
         STM,R10  DBKGHPSD-DBKGH+1,R5  INSERT PSD IN HEADER                     
         AI,R5    DBKGHDT-DBKGH+1                                               
         LI,R6    TIMEC                                                         
         STB,R6   R5                                                            
         CAL1,8   R5                INSERT TIME/DATE                            
         LB,R2    TCBPOINT          BKG STI INDEX                               
         LD,R2    STIRTSB,R2        CALPUSH RTS POINTER                         
         AI,R2    -5                LOC OF PUSHED R15                           
         STW,R2   WXLWA,R7          SET LWA OF REG DUMP                         
         AI,R2    -15               LOC OF PUSHED R0                            
         STW,R2   WXFWA,R7          SET FWA OF REG DUMP                         
         LCW,R2   R2                DISPLACEMENT FROM ADDR OF                   
         STW,R2   WXBAD,R7          SAVED REGS TO ADDR OF REGS                  
         LI,R0    0                                                             
         STW,R0   WXBAL,R7          NO POST-PRINT ROUTINE                       
         LW,R1    K:PMD1                                                        
*        REGISTER DUMP FLAGS SET IF SET FOR ANY PMD                             
         CI,R1    X'F800'                                                       
         BAZ      %+2               B IF NO TEXT DUMP                           
         AI,R0    MEBC              SET EBCDIC FLAG                             
         CI,R1    X'F8'                                                         
         BAZ      %+2               B IF NOT A SHORT LINE                       
         AI,R0    M4WD              SET 4-WORD LINE FLAG                        
         LI,R6    BXFLAGS                                                       
         STB,R0   *R7,R6            SET FLAGS                                   
         BAL,R8   DUMP              DUMP REGS                                   
         B        DBIOER            DUMP I/O ERROR                              
         LI,R0    0                                                             
         STW,R0   WXBAD,R7          RESET BUFFER-ADDRESS DISPLACEMENT           
DBKG50   LI,R6    0                                                             
         LI,R1    X'8080'           USED TO RESET FLAGS                         
         LI,R0    0                                                             
DBKG55   LW,R5    K:PMD,R6                                                      
         BNEZ     DBKG60            B IF A DUMP REQUEST                         
         AI,R6    1                                                             
         CI,R6    4                                                             
         BL       DBKG55            LOOK AT NEXT PMD CELL                       
         DISABLE                    CHECK KEYIN PMD                             
         LW,R5    K:PMD+4                                                       
         BNEZ     DBKG60            B IF NON-ZERO                               
         ENABLE                                                                 
DBKGX    RES      0                                                             
         LW,R0    K:CTST                                                        
         CI,R0    4                                                             
         BANZ     %+2               B IF NORMAL TERMINATION                     
         CAL1,9   3                 ABORT                                       
         CAL1,9   1                 EXIT                                        
*                                                                               
DBKG60   STW,R0   K:PMD,R6          RESET (READY FOR NEXT TIME)                 
         LW,R2    K:PMD1            GET CURRENT FLAGS                           
         LCW,R3   R6                                                            
         SLS,R1   0,R3                                                          
         STS,R0   K:PMD1            RESET CURRENT FLAGS                         
         ENABLE                                                                 
         LH,R4    R5                UNPACK FDA,LDA                              
         AND,R4   XFFFF                                                         
         SLD,R4   1                 DA TO WA                                    
         AI,R5    -1                LWA+1 TO LWA                                
         AND,R5   X1FFFF            0 IS TREATED AS X'20000'                    
         CI,R4    X'10'             FORCE FWA ABOVE REGS                        
         BGE      %+2                                                           
         LI,R4    X'10'                                                         
         STW,R4   WXFWA,R7          SET FWA                                     
         STW,R5   WXLWA,R7          SET LWA                                     
         LI,R0    MVIRT                                                         
         SLS,R2   0,R6              ADJUST K:PMD1 FLAGS FOR THIS DUMP           
         CI,R2    X'8000'                                                       
         BAZ      %+2               B IF NO TEXT DUMP                           
         AI,R0    MEBC              TEXT DUMP FLAG                              
         CI,R2    X'80'                                                         
         BAZ      %+2               B IF NOT A SHORT-LINE DUMP                  
         AI,R0    M4WD              4-WORD LINE FLAG                            
         LI,R6    BXFLAGS                                                       
         STB,R0   *R7,R6            SET FLAGS                                   
         LW,R6    R7                SET UP HEADER                               
         AI,R6    WXBUF-1                                                       
         LI,R5    32                                                            
         LW,R4    BLANKS                                                        
         STW,R4   *R6,R5                                                        
         BDR,R5   %-1                                                           
         LI,R6    X'CC'             VFC: SKIP 12 LINES                          
         LI,R5    WXBUF*4           BX TO BUFFER                                
         STB,R6   *R7,R5                                                        
         BAL,R8   DUMP              DUMP THE CURRENT REGION                     
         B        DBIOER            DUMP I/O ERROR                              
         B        DBKG50            B TO GET NEXT DUMP                          
*                                                                               
DODCB    GEN,8,16,4,4  5,1,0,3      LENGTH,VFC,UNSET,OPLABEL CODE               
         GEN,8,16,8    3,0,DO       NRT,UNSET,OPLABEL INDEX                     
         DATA     0,128**17,0       UNSET,RSZ,UNSET                             
*                                                                               
         BOUND    8                                                             
BKGPLIM  TEXT     ' PAGELIM'                                                    
BKGTIME  TEXT     ' TIMEOUT'                                                    
BKGABT   TEXT     '  ABORT '                                                    
BKGEXIT  TEXT     '  EXIT  '                                                    
DBKGH    TEXT     '1BKG'                                                        
DBKGHTYP TEXT     '        '                                                    
         TEXT     '  PSD:  '                                                    
DBKGHE   RES      0                                                             
DBKGHPSD RES      0                                                             
DBKGHDT  EQU      %+5                                                           
*                                                                               
DBIOER   LCI      DBIOERME-DBIOERM  DUMP IO ERROR                               
         LM,R8    DBIOERM                                                       
         CAL1,2   R8                TYPE THE ERROR MESSAGE                      
         BAL,R8   DBKGZLCH          CANCEL BKG DUMPS                            
         B        DBKGX             EXIT                                        
*                                                                               
DBIOERM  GEN,8,24 2,0               TYPE CAL CODE                               
         GEN,1,31  1,X'10'          MESSAGE POINTER AND WAIT                    
         DATA     11                                                            
         TEXTC    '  PMD IO ERROR'                                              
DBIOERME RES      0                                                             
*                                                                               
DBNOTS   LCI      DBNOTSME-DBNOTSM  NOT ENUF TSPACE                             
         LM,R8    DBNOTSM                                                       
         CAL1,2   R8                TYPE THE MESSAGE                            
         BAL,R8   DBKGZLCH          CANCEL BKG DUMPS                            
         LI,R11   1                 WILL RESET PMD FLAG                         
         B        A02               B TO SKIP DUMP                              
*                                                                               
DBNOTSM  GEN,8,24 2,0               TYPE CAL CODE                               
         GEN,1,31  1,X'10'          MESSAGE POINTER AND WAIT                    
         DATA     11                                                            
         TEXTC    '  NO PMD TSPACE'                                             
DBNOTSME RES      0                                                             
*                                                                               
DBKGZLCH LI,R4    0                 WIPE OUT BKG DUMP REQUESTS                  
         LI,R5    5                                                             
         STW,R4   K:PMD-1,R5                                                    
         BDR,R5   %-1                                                           
         LI,R5    X'FEFE'                                                       
         STS,R4   K:PMD1            RESET PMD FLAGS                             
         B        *R8                                                           
*                                                                               
BKGIDLM  GEN,8,24  2,0              TYPE FPT                                    
         GEN,1,31  1,X'10'          MESSAGE POINTER AND WAIT                    
         DATA     11                MESSAGE POINTER                             
         TEXTC    '!!BACKGROUND IDLE'                                           
BKGIDLME RES      0                                                             
*                                                                               
TYPEFPT  DATA     X'02000000'                                                   
         GEN,1,31  1,X'10'          MESSAGE POINTER AND WAIT                    
         DATA     K:MSG13                                                       
PT%      RES      0                                                             
BKGNAME  DATA     'BKG '                                                        
JCPLMID  DATA     'SP'              LOAD MODULE ID FOR JCP                      
         TEXT     'JCP     '                                                    
         DO       #DFACNT                                                       
         TEXT     '        '                                                    
         FIN                        #DFACNT                                     
         OLAYEND                                                                
         END                                                                    
