ASMB,R
      NAM MES06,7 92903-16364 REV.1913  790111 1345 
      HED *               -MES06- 
* 
*     SOURCE 92903-18364
* 
      SPC 2 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
      SPC 2 
      SUP 
* 
**********************************************************************
*                                                                    *
*                   THIS SUBROUTINE IS CALLED BY THE SEGMENT ANSW1   *
*  OF THE FORMG PROGRAM TO WRITE AN ERROR MESSAGE ON THE TERMINAL.   *
*                   THE ERROR MESSAGE IS PRINTED ON LINE 24 OF THE   *
*  SCREEN AND THE CURSOR IS MOVED TO THE WRONG FIELD.                *
*                   THIS SUBROUTINE IS CALLED WITH TWO PARAMETERS :  *
*                                                                    *
*           - PAR#1 =  ERROR MESSAGE # TO OUTPUT                     *
*           - PAR#2 =  WRONG FIELD # ON THE SCREEN                   *
*                                                                    *
**********************************************************************
* 
* 
      ENT MES06     ENTRY POINT 
      EXT EXEC
      EXT .ENTR 
      EXT &REMP 
      EXT &MVW
      COM ILU       TERM. LU
* 
*  GET CALLING PARAMETERS AND INITIALISE
* 
NMESS NOP           FIRST PARM. ADDRESS 
NOF   NOP           SECD. PARM. ADDRESS 
MES06 NOP           ENTRY POINT 
      JSB .ENTR     SUBR. TO GET
      DEF NMESS     PARM. ADDRESS 
      LDA BUFAD     INITIALIZE
      LDB SPACE     ERROR MESSAGE 
      JSB &REMP     BUFFER
      DEC -35       TO BLANK
      LDA BUFA1     INITIALIZE
      LDB NULL      TAB BUFFER
      JSB &REMP      TO NULL
      DEC -50 
* 
*  MOVE ERROR MESSAGE IN OUTPUT BUFFER
* 
      LDA NMESS,I   GET ERROR MESSAGE # 
      ADA AMES0     COMPUTE MESSAGE 
      LDB A,I       ADDRESS 
      STB P1        STORE IT
      CMB,INB       MINUS STARTING ADDRESS
      STB IST        OF MESSAGE IN IST
      INA            COMPUTE NEXT MESSAGE 
      LDA A,I       STARTING ADDRESS
      ADA IST       COMPUTE MESSAGE LENGTH
      STA P2        STORE IT
      LDA P1        BUFFER SOURCE ADDRESS 
      LDB BUFAD     BUFFER DEST ADDRESS 
      JSB &MVW      MOVE WORDS
P2    NOP           BUFFER LENGTH 
* 
*  INCLUDE # OF NECESSARY TABS
* 
      LDA NOF,I     GET WRONG FIELD # 
      CMA,INA       MAKE IT NEG.
      ISZ A         INCREMENT: IS FIRST FIELD ? 
      RSS           NO
      JMP WRIT      YES OUTPUT BUFFER 
      STA P3        STORE NEG. # OF TABS
      LDA BUFA1     TAB BUFFER ADDRESS
      LDB TAB       TAB 
      JSB &REMP     INCLUDE TABS
P3    NOP           IN BUFFER 
* 
*  WRITE MESSAGE
* 
WRIT  JSB EXEC      WRITE EXEC CALL 
      DEF *+5       RETURN POINT
      DEF D.2       CODE EXEC 
      DEF ILU       CONTROL WORD
      DEF BUF       BUFFER LOCATION 
      DEF ILN       BUFFER LENGTH 
* 
*  RETURN TO CALLING PROGRAM
* 
      JMP MES06,I 
* 
*  BUFFER DATA
* 
BUF   BYT 33,130,33,46,141,62,62,162,60,103  FORMAT OFF:POS.CURSOR
      BYT 33,112,15,12,40,0 
      BYT 33,46,144,103 INVERSE VIDEO BLINKING
      ASC 2,ERRO
      BYT 122,33,46,144,100 END ENHANCEMENT 
      ASC 2,  : 
BUFER BSS 35        MESSAGE BUFFER
      BYT 33,127,33,110 FORMAT ON * HOME CURSOR 
BUF1  BSS 50        TAB BUFFER
      BYT 33,142    KEYBOARD ENABLE 
EBUF  BYT 0,137     SUPPRESS <CR>,<LF>
* 
* STORAGE , CONSTANTS ..
* 
BUFAD DEF BUFER     BUFF. ADDRESS 
BUFA1 DEF BUF1      TAB BUFFER ADDRESS
A     EQU 0         A REGISTER
STAD  EQU BUF       BUFFER STARTING ADDRESS 
LTAD  EQU EBUF      BUFFER LAST ADDRESS 
IST   NOP 
P1    NOP           SOURCE ADDRESS BUFFER ADDRESS 
ILN   ABS LTAD-STAD+1 BUFFER LENGTH 
SPACE BYT 40,40 
NULL  BYT 0,0 
TAB   BYT 33,111
D.2   DEC 2 
* 
*  MESSAGE ADDRESS
* 
AMES0 DEF AMES1-1 
AMES1 DEF MES1
      DEF MES2
      DEF MES3
      DEF MES4
      DEF MES5
      DEF MES6
      DEF MES7
      DEF MES8
      DEF MES9
      DEF MES10 
      DEF MES11 
      DEF MES12 
      DEF MES13 
      DEF MES14 
      DEF MES15 
      DEF MES16 
      DEF MES17 
      DEF MES18 
      DEF MES19 
      DEF MES20 
      DEF MES21 
      DEF MES22 
      DEF MES23 
      DEF MES24 
      DEF MES25 
      DEF MES26 
      DEF MES27 
      DEF MES28 
      DEF MES29 
      DEF MES30 
      DEF MES31 
      DEF MES32 
      DEF MES33 
      DEF MES34 
      DEF MES35 
      DEF MES36 
      DEF MES37 
      DEF MES38 
* 
*  MESSAGE STORAGE
* 
MES1  ASC 15,Field must be blank or integer 
MES2  ASC 12,No more lights available 
MES3  ASC 10,Illegal light number 
MES4  ASC 13,Light reserved for system
MES5  ASC 12,Field must be blank or X 
MES6  ASC 11,Illegal string length
MES7  ASC 19,No key assigned to NEXT ENTRY function 
MES8  ASC 18,No key assigned to CONTINUE function 
MES9  ASC 20,No key assigned to DELETE ENTRY function 
MES10 ASC 13,Illegal display value type 
MES11 ASC 10,Field must be blank
MES12 ASC 12,Illegal character input
MES13 ASC 23,CONTINUE not allowed since no display defined
      ASC  9,for this question
MES14 ASC 23,The displayed value (default value)and the ans 
      ASC 12,wer must be of same type 
MES15 ASC 14,Illegal Logical Unit number
MES16 ASC 23,Displayed value and answer max string length m 
         ASC  6,ust be equal
MES17 ASC  9,Missing file name
MES18 ASC 12,Illegal cartridge number 
MES19 ASC 22,NEXT ENTRY cannot be defined in a U question 
MES20 ASC 1,XX
MES21 ASC 1,XX
MES22 ASC 17,No media defined for data storage
MES23 ASC 1,
MES24 ASC 23,To use NEXT ENTRY a find in a detail data set
      ASC 11,must have been defined 
MES25 ASC  9,Illegal file name
MES26 ASC 11,Must define a function 
MES27 ASC 13,Missing display item name
MES28 ASC 13,Missing display item type
MES29 ASC 14,Missing display program name 
MES30 ASC  9,Unknown operation
MES31 ASC  1,XX 
MES32 ASC 13,Illegal file security code 
MES33 ASC 14,Display value defined twice
MES34 ASC 16,Missing display value definition 
MES35 ASC 19,Data Storage exceeds maximum capacity
MES36 ASC 22,No more than 4 SUMMARY items may be defined
MES37 ASC 25,Field must be BLANK or 'O' or 'S' or 'OS' or 'SO'
MES38 ASC 1,-1
* 
* 
      END MES06 
                                                                                                                                                                                                                                                        