ASMB,R
      NAM HLP01,7  92903-16354 REV.1805  770809 
* 
*     SOURCE 92903-18354
* 
      SPC 2 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
      SPC 2 
      SUP 
* 
**********************************************************************
*                                                                    *
*                   THIS SUBROUTINE IS USED TO PRINT A HELP MESSAGE  *
*  ON LINES 23 AND 24 OF THE TGP SCREENS                             *
*                   THE CURSOR IS POSITIONEDAT THE FIELD WHERE THE   *
*  HELP SOFT KEY WAS PRESSED.                                        *
*                   THIS SUBROUTINE IS CALLED WITH TWO PARAMETERS :  *
*                                                                    *
*           - PAR#1 =  HELP  MESSAGE # TO OUTPUT                     *
*           - PAR#2 =  HELP  FIELD # ON THE SCREEN                   *
*                                                                    *
**********************************************************************
* 
* 
      ENT HLP01     ENTRY POINT 
      EXT EXEC
      EXT .ENTR 
      EXT &REMP 
      EXT &MVW
      COM ILU       TERM. LU
* 
*  GET CALLING PARAMETERS 
* 
NMESS NOP           FIRST PARM. ADDRESS 
NOF   NOP           SECD. PARM. ADDRESS 
HLP01 NOP           ENTRY POINT 
      JSB .ENTR     SUBR. TO GET
      DEF NMESS     PARM. ADDRESS 
* 
* 
*  MOVE HELP  MESSAGE IN OUTPUT BUFFER
* 
      LDA NMESS,I   GET ERROR MESSAGE # 
      SZA,RSS       IS 0 ?
      JMP HPLC      YES NO MESSAGE
      ADA AMES0     COMPUTE MESSAGE 
      LDB A,I       ADDRESS 
      STB P1        STORE IT
      CMB,INB       MINUS STARTING ADDRESS
      STB IST        OF MESSAGE IN IST
      INA            COMPUTE NEXT MESSAGE 
      LDA A,I       STARTING ADDRESS
      ADA IST       COMPUTE MESSAGE LENGTH
      STA P2        STORE IT
      LDA P1        BUFFER SOURCE ADDRESS 
      LDB BUFAD     BUFFER DEST ADDRESS 
      JSB &MVW      MOVE WORDS
P2    NOP           BUFFER LENGTH 
* 
      LDB BUFAD     COMPUTE CURRENT 
      ADB P2        ADDRESS IN OUTPUT BUFFER
* 
      LDA BUF1      INCLUDE FORMAT ON 
      STA B,I       IN OUTPUT BUFFER
      INB           INCREMENT ADDRESS IN OUT. BUFFER
* 
      LDA D.10      COMPUTE OUTPUT BUFFER LENGTH
      ADA P2
      STA ILN       STORE IT
      JMP HPLB
* 
HPLC  LDA D.10
      STA ILN 
      LDB BUFAD 
      LDA BUF1
      STA B,I 
      INB 
* 
* NOW INCLUDE TABS IN BUFFER
* 
HPLB  LDA NOF,I     GET HELP  FIELD # 
      CPA D.1       IS 1 ?
      JMP HLPA      YES NO TABS 
      ADA .D1       DECREMENT 
      STA P5        STORE # OF FIELD
      ADA ILN       INCREMENT OUTPUT BUFFER 
      STA ILN       LENGTH
      LDA P5        GET FIELD # 
      CMA,INA       MAKE IT NEG 
      STA P4
      LDA B 
      STB P2        SAVE B
      LDB TAB 
      JSB &REMP     MOVE TABS IN BUFFER 
P4    NOP 
* 
      LDB P2        RESTORE B 
      LDA P5        INCREMENT ADDRESS IN
      ADB A 
* 
HLPA  LDA BUFA2 
      JSB &MVW      INCLUDE KEY ENABLE
      DEC 3         IN BUFFER 
* 
      JSB EXEC      WRITE MESSAGE 
      DEF *+5 
      DEF D.2 
      DEF ILU 
      DEF BUF 
      DEF ILN 
* 
      JMP HLP01,I 
* 
* 
*  BUFFER DATA
* 
BUF   BYT 33,130,33,46,141,62,62,162,60,103  FORMAT OFF:POS.CURSOR
      BYT 33,112    CLEAR DISPLAY 
BUFER BSS 140       MESSAGE BUFFER
* 
* STORAGE , CONSTANTS ..
* 
BUFAD DEF BUFER     BUFF. ADDRESS 
BUFA2 DEF BUF2
A     EQU 0         A REGISTER
B     EQU 1         B REGISTER
IST   NOP 
P1    NOP           SOURCE ADDRESS BUFFER ADDRESS 
P5    NOP 
ILN   NOP             BUFFER LENGTH 
TAB   BYT 33,111
BUF1  BYT 33,127    FORMAT ON 
BUF2  BYT 0,0,0,33,142,137                     ERASE h ,KEY.ENABLE
.D1   DEC -1
D.10  DEC 10
D.1   DEC 1 
D.2   DEC 2 
* 
*  MESSAGE ADDRESS
* 
AMES0 DEF AMES1-1 
AMES1 DEF MES1
      DEF MES2
      DEF MES3
      DEF MES4
      DEF MES5
      DEF MES6
      DEF MES7
      DEF MES8
      DEF MES9
      DEF MES10 
      DEF MES11 
* 
*  MESSAGE STORAGE
* 
MES1  BYT 33,46,144,112 
      ASC 22, Name (maximum of 6 alphanumeric characters) 
      ASC 18, : It uniquely identifies each 
      BYT 33,46,144,112 
      ASC 14, transaction specification.
      BYT 33,46,141,53,65,62,103,0  POSITION  CURSOR -  81
* 
MES2  BYT 33,46,144,112 
      ASC 22, The name (6 alphanumeric characters) or num 
      ASC 18,ber (from 0 to 9999) uniquely
      BYT 33,46,144,112 
      ASC 20, identify each transaction specification 
      BYT 33,46,141,53,64,60,103,0  POSITION  CURSOR -  81
* 
MES3  BYT 33,46,144,112 
      ASC 22, The Disc File name is composed of 6 printab 
      ASC 18,le alphanumeric characters starting
* 
      BYT 33,46,144,112 
      ASC 15, with an alphabetic character. 
      BYT 33,46,141,53,65,60,103,0  POSITION  CURSOR -  81
* 
MES4  BYT 33,46,144,112 
      ASC 22, Each disc cartridge in an RTE system is ide 
      ASC 18,ntified by a Cartridge Reference # 
* 
      BYT 33,46,144,112 
      ASC 17, assigned by the system operator.
      BYT 33,46,141,53,64,66,103,0  POSITION  CURSOR -  81
* 
MES5  BYT 33,46,144,112 
      ASC 22, File name of an output device selected amon 
      ASC 18,g those defined when installing
* 
      BYT 33,46,144,112 
      ASC  4, DATACAP 
      BYT 33,46,141,53,67,62,103,0  POSITION  CURSOR -  81
* 
MES6  BYT 33,46,144,112 
      ASC 22, Number (0=<N<=999) used to access the trans 
      ASC 18,action specification from the HP3070 
* 
      BYT 33,46,144,112 
      ASC  6, terminals.
      BYT 33,46,141,53,66,70,103,0  POSITION  CURSOR -  81
* 
MES7  BYT 33,46,144,112 
      ASC 22, The security code (-32768=<SC<=32767) preve 
      ASC 18,nts access to the transaction speci- 
* 
      BYT 33,46,144,112 
      ASC 18, fication by unauthorized personnel. 
      BYT 33,46,141,53,64,64,103,0  POSITION  CURSOR -  81
* 
MES8  BYT 33,46,144,112 
      ASC 22, User written modules are user subroutines d 
      ASC 18,esigned to allow specific valida-
* 
      BYT 33,46,144,112 
      ASC 22, tions, display or storage operations to be
      ASC 18,performed during the transaction.
* 
MES9  BYT 33,46,144,112 
      ASC 22, The data base name must be identical to the 
      ASC 18, name given in the data base schema
* 
      BYT 33,46,144,112 
      ASC  9, when creating it. 
      BYT 33,46,141,53,66,62,103,0  POSITION  CURSOR -  81
* 
MES10 BYT 33,46,144,112 
      ASC 22, The data base security code must be identic 
      ASC 18,al to the security code given in the 
* 
      BYT 33,46,144,112 
      ASC 18, data base schema when creating it.
      BYT 33,46,141,53,64,64,103,0  POSITION  CURSOR -  81
* 
MES11 ASC 1,-1
* 
* 
      END HLP01 
                                                                                                                                                                            