ASMB
   HED RTE-IV LARGEST PARTITION EVER
      NAM MADSP,7 . 92903-16001 REV.1913  781219
  SPC 3 
**********************************************************************
*                                                                    *
*     NAME:   MADSP     MAXIMUM ADDR SPACE                           *
*     SOURCE: &MADSP    92903-18039                                  *
*     BINARY: %MADSP    ----NONE---    PART OF  %GPLB4  92903-16001  *
*                                                                    *
*     PGMR:   FRANCOIS GAULLIER                                      *
*                                                                    *
**********************************************************************
      SPC 2 
*     **************************************************************
*     * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS    *
*     * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
*     * PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
*     * OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
*     **************************************************************
  SPC 3 
      EXT .ENTR,$DLP,$SDA,$PLP,$OPSY
      ENT MADSP 
      SUP 
  SPC 2 
*   THIS SUBROUTINE RETURN THE 3 MAXIMUM ADDRESS SPACE
*      RETURN THE # OF PAGES, INCLUDED BASE PAGE. 
* 
*     CALLING SEQUENCE: 
*        CALL MADSP(IBUF) 
*          IBUF(1) = MAXIMUM PROGRAM ADDRESS SPACE WITHOUT SYST. COMMMON
*          IBUF(2) = MAXIMUM PROGRAM ADDRESS SPACE WITH SYST. COMMON
*          IBUF(3) = MAXIMUM PROGRAM ADDRESS SPACE WITH TABLE AREA II 
* 
.BUF  NOP 
MADSP NOP 
      JSB .ENTR 
      DEF .BUF
* 
      CLA           SET ERROR INDICATOR 
      STA .BUF,I
* 
      LDA $OPSY     GET SYSTEM TYPE 
      CPA DM9       RTE-IV ?
      RSS 
      JMP MADSP,I   NO, RETURN
  SPC 1 
      XLA $DLP      GET TYPE IV WITHOUT SSGA
      ALF,ALF       SET IT INTO NUMBER
      RAR,RAR       OF PAGES
      CMA,INA       AND COMPUTE PARTITION 
      ADA D32       SIZE
      INA           FOR BASE PAGE 
      STA .BUF,I    AND RETURN IT TO THE USER 
      ISZ .BUF
* 
      XLA $SDA      GET TYPE IV WITH SSGA 
      CMA,INA       COMPUTE NUMBER OF PAGE
      ADA D32 
      INA           FOR BASE PAGE 
      STA .BUF,I
      ISZ .BUF
* 
      XLA $PLP      GET TYPE III
      ALF,ALF       SET IT IN NUMBER OF PAGES 
      RAR,RAR 
      CMA,INA       COMPUTE NUMBER OF PAGES 
      ADA D32 
      INA           FOR BASE PAGE 
      STA .BUF,I
      JMP MADSP,I 
  SPC 2 
DM9   DEC -9
D32   DEC 32
      END 
                                                                                                                                                            