ASMB,C,Q
      HED << 09580 TRAP SET ROUTINE >>
      NAM TRPN5,30 92425-1X070 REV.2001 791129
* 
*---------------------------------------------------------------
* 
*     NAME: TRPNT 
*   SOURCE: 92425-18070 
*    RELOC: 92415-1X070 
*     PRGM: DICK LAMPMAN
************************************************************************* 
*    (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS             * 
*    RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,             *
*   REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT        * 
*   THE PRIOR WRITTED CONSENT OF HEWLETT-PACKARD COMPANY.               * 
************************************************************************* 
* 
* ENTRY POINTS: 
* 
      ENT TRPNT 
* 
* 
* 
* EXTERNAL REFERENCES:
* 
      EXT $LIBR,$LIBX 
      EXT TABL$,STN$,TRTBL,TREND
      EXT LUTRU 
* 
* 
* 
***** 
* 
** TRPNT ** SET A BIT IN THE TRAP TABLE 
* 
*     LDA TRAP NUMBER 
*     LDB STATION NUMBER (SESSION LU OF CRT)
*     JSB TRPNT 
*     RETURN1       TRAP TABLE FULL & THIS ENTRY NOT THERE ALREADY
*     RETURN2       SUCCESS 
* 
* NOTE: IF NO ENTRY WITH THAT TRAP NBR EXISTS, THIS 
*       ROUTINE WILL MAKE ONE WITH PRIORITY 99 AND
*       WITH THE ENABLE BIT AND THE SEQ NBR CLEARED.
* 
******
* 
TRPNT NOP 
* 
      JSB $LIBR     TURN OFF THE INTERRUPT SYSTEM.
      NOP 
* 
      STA TRNUM     SAVE TRAP # 
      STB LUSES     SAVE SESSION LU.
* 
      JSB LUTRU     GET SYSTEM LU.
      DEF *+3 
      DEF LUSES 
      DEF LUSYS 
* 
      LDB TRTBL 
FINDT LDA TREND     FIND TRAP TABLE FOR STN # 
      CMA,INA 
      ADA .B. 
      SSA,RSS       END OF TABLE? 
      JMP ERTN        YES, ERROR RETURN 
      LDA .B.,I       NO,  GET STATION #
      CPA LUSYS     SAME AS REQUEST?
      JMP SETTR       YES, SET TRAP 
      ADB STN$        NO,  TRY AGAIN
      JMP FINDT 
      SPC 5 
SETTR LDA TRNUM     TEST FOR LEGAL TRAP # 
      SZA,RSS       ZERO? 
      JMP ERTN        YES 
      SSA           NEGATIVE? 
      JMP ERTN        YES 
      CMA,INA       COMPLEMENT TRAP NUMBER
      ADA TABL$ 
      SSA           TRAP # > TABLE SIZE 
      JMP ERTN        YES 
      ADB D3        FORM 'SEARCH TBL' FLAG
      LDA BIT15 
      STA .B.,I       ADDRESS & SET #0
      ADB TRNUM     FORM ADDRS OF TRAP CELL 
      LDA .B.,I     GET CONTENTS OF TRAP CELL 
      IOR BIT15     SET TRAP BIT
      STA .B.,I     PUT INTO TABLE
      ISZ TRPNT     RETURN (P+1)
ERTN  JSB $LIBX     RETURN (P)
      DEF TRPNT 
      SKP 
*        CONSTANTS AND VARIBLES 
* 
      SPC 2 
.A.   EQU 0         A REGISTER
.B.   EQU 1         B REGISTER
TRNUM NOP           TRAP NUMBER 
LUSYS NOP           SYSTEM LU OF STATION
      SPC 5 
LUSES OCT 0        TEMP STORAGE FOR SESSION LU. 
D3    DEC 3 
BIT15 OCT 100000
      END 
                                                                                                                                                                                      