ASMB,Q,C
      NAM .XLA,6 92425-1X067 REV.2001 791218
*     NAME: .XLA
*   SOURCE: 92425-18067 
*   RELOC : 92425-1X067 
*     PRGM: DICK LAMPMAN
************************************************************************* 
*    (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS             * 
*    RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,             *
*   REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT        * 
*   THE PRIOR WRITTED CONSENT OF HEWLETT-PACKARD COMPANY.               * 
************************************************************************* 
      ENT .XLA
      EXT .ZPRV 
      SPC 1 
BPA3  EQU 1744B     FWA OF DISC RESIDENT BASE PAGE FOR DMS SYSTEMS
XLA   OCT 101724
      SPC 1 
*  PURPOSE: 
*   THIS CODE WILL ALLOW PROGRAMS THAT GENERALLY WILL GO AFTER
*   DATA THAT IS IN A SYSTEM MAP FOR RTE-IV SYSTEMS, BUT ALLOW
*   THE SAME PROGRAMS TO WORD IN AN RTE-III & RTE-II SYSTEM.
      SPC 1 
.TMP1 NOP 
.TMP2 NOP 
      SPC 1 
.XLA  NOP           ENTRY TO EXECUTE THE XLA INSTRUCTION
      JSB .ZPRV     MAKE CALLABLE FROM TYPE 6 CODE
      DEF LIBX
      STA .TMP1     SAVE A-REG CONTENTS 
      LDA O2        CHECK IF A MAPPING SYSTEM?
      CPA BPA3      (RTE-2?)
      JMP .XLA1     NO, MUST BE A MAPPING SYSTEM
      LDA .XLA,I    GET OPERAND ADDRESS 
      STA .TMP2     SAVE IT 
      LDA .TMP1     RESTORE A-REG 
      LDA .TMP2,I   AND GET THE CONTENTS
      ISZ .XLA      BUMP TO P+2 RETURN
LIBX  JMP .XLA,I    AND EXIT
      DEF .XLA
      SPC 1 
.XLA1 LDA .XLA      GET P+1 ADDRESS 
      CMA,INA       DECREMENT WITHOUT DISTURBING
      CMA           THE E-REG 
      STA .XLA      AND PUT BACK P+0 ADDRESS
      LDA XLA       GET THE REAL INSTRUCTION
      STA .XLA,I    AND CHANGE THE JSB TO XLA 
      LDA .TMP1     RESTORE A-REG 
      JMP LIBX      AND GO EXECUTE THE INSTRUCTION
      SPC 1 
O2    OCT 2 
      END 
                                                                                                        