ASMB,Q,C
      HED "KGET" SAME AS IGET BUT THRU SYSTEM MAP IF ONE 5-78 (DLB) 
      NAM KGET,7 92425-1X066 REV.2001 791218
*     NAME: KGET
*   SOURCE: 92425-18066 
*   RELOCE: 92425-1X066 
*     PRGM: DICK LAMPMAN
************************************************************************* 
*    (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS             * 
*    RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,             *
*   REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT        * 
*   THE PRIOR WRITTED CONSENT OF HEWLETT-PACKARD COMPANY.               * 
************************************************************************* 
      ENT KGET
      SPC 1 
A     EQU 0 
B     EQU 1 
BPA3  EQU 1744B 
* PURPOSE:  TO ALLOW FTN PROGRAM TO GET DATA FROM SYSTEM AND
*           BASE PAGE.
* CALLED: 
*            IVALU = KGET(IADDRS) 
* WHERE:
*          IADDRS = DESIRED ADDRESS OF WORD TO GET THUR SYSTEM MAP. 
*          IVALU  = VALUE OF DESIRED WORD.
      SPC 1 
KGET  NOP           ENTRY 
      LDA BPA3      CHECK IF MAPPING SYSTEM?
      CPA O2        CHECK IF MAPPED SYSTEM? 
      JMP KGET1     YES, CONTINUE 
      LDA LDAAI     NO, MUST BE RTE-II OR DOS 
      STA IOPTN 
      LDA JMPBI     GET THE JMP B,I INSTRUCTION 
      STA IOPTN+1 
KGET1 LDB KGET,I    GET RETURN ADDRESS
      ISZ KGET      BUMP TO PASSED PARAMETER ADDRESS
      LDA KGET,I    GET PARAMETER ADDRESS 
LDAAI LDA A,I       GET PARAMETER VALUE (=ADDRESS)
IOPTN XLA A,I       OR LDA A,I
JMPBI JMP B,I       AND EXIT WITH A-REG = ANSWER
O2    OCT 2 
      END 
                                                                                                                                                                                  