ASMB,Q,C  
      NAM DALOC 92425-18060 REV.2001 791115 
*-------------------------------------------------------------------
* 
*      RELOC.       92425-1X060 
*      SOURCE       92425-18060 
*                     791015    REV. 2001 
* 
*      HP 92425C TEST SYSTEM SOFTWARE IS THE PROPRIETARY
*      MATERIAL OF THE HEWLETT-PACKARD COMPANY.  USE AND
*      DISCLOSURE THEREOF ARE RESTRICTED BY WRITTEN AGREEMENT.
* 
*      (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.
*      ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM
*      MAY BE PHOTOCOPIED, REPRODUCED OR TRANSLATED 
*      TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR
*      WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY.
* 
*-------------------------------------------------------------------
* 
*     THIS PROGRAM IS RESPONSIBLE FOR DEALLOCATING
*  CLASS BUFFERS.  IT OPERATES BY FIRST RETRIEVING
*  THE STATION NUMBER FROM THE CALLING SEQUENCE OR
*  MAKING A CALL TO ISN.  THE CLASS NUMBER OF THE FIRST 
*  BUFFER IN SAM ATTACHED TO THE AFOREMENTIONED STATION 
*  IS LOCATED IN THE CORE RESIDENT TABLE. AFTER 
*  RETRIEVING THIS NUMBER THE CLASS NUMBERS ASSOCIATED
*  WITH THE REST OF THE BUFFERS IN SAM ARE RETRIEVED
*  USING CLASS I/O GET REQUESTS.
* 
      EXT RMPAR 
      EXT RTCLN,STCLN,IPUT
      EXT ERROR 
      EXT ISN 
      EXT EXEC
      ENT DALOC 
* 
* 
DALOC NOP 
      JSB RMPAR     RETRIEVE STATION #
      DEF *+2 
      DEF IPRAM 
      LDA IPRAM     SEE IF IT IS = 0
      SZA 
      JMP CONT      NO
      JSB ISN       YES IT IS SO GET # FROM ISN 
      DEF *+2 
      DEF DUMMY 
      STA IPRAM 
      SZA,RSS       MAKE SURE STATION EXISTS
      JMP ERR1      NO, WELL TELL THE WORLD 
CONT  JSB RTCLN     GET CLASS NUMBER. 
      DEF *+3 
      DEF IPRAM 
      DEF IFCLS 
* 
      LDA IFCLS     GET CLASS NUMBER
      SZA,RSS       MAKE SURE CLASS # IS .NE. 0 
      JMP FINI      ALL DONE IF NOTHING TO DEALLOCATE.
LOOP  AND MASK      MASK OUT BITS 13 AND 14 TO INDICATE 
      STA ICL       TO THE SYSTEM THAT WE WANT TO RELEASE 
      JSB EXEC      THE BUFFER AND THE CLASS NUMBER 
      DEF *+5       CLASS I/O GET 
      DEF GET 
      DEF ICL 
      DEF IBUF
      DEF .2        RETRIEVE ONLY THE FIRST TWO WORDS 
      LDA IBUF      CHECK TO SEE IF WE'RE DONE
      CPA IFCLS 
      JMP FINI
      LDA IBUF      GO AGAIN
      JMP LOOP
      SKP 
* 
* 
FINI  CLA           NOW CLEAR THE CLASS NO. FOR THIS STATION. 
      STA IFCLS 
      JSB STCLN 
      DEF RTN 
      DEF IPRAM 
      DEF IFCLS 
RTN   JSB EXEC      NOW INDUCE SELF SLEEP 
      DEF *+2 
      DEF .6
* 
      SPC 2 
ERR1  JSB ERROR 
      DEF *+3 
      DEF IERR
      DEF IERMS 
      JMP RTN 
      SKP 
* 
* CONSTANTS AND TEMPORARY STORAGE 
* 
IBADR DEF IBUF+1
IPRAM BSS 5 
ADDR  NOP 
IFCLS NOP 
IBUF  BSS 2 
MASK  OCT 17777 
.7    OCT 7 
DUMMY NOP 
A     EQU 0 
B     EQU 1 
ICL   NOP 
GET   DEC 21
.2    OCT 2 
.6    OCT 6 
IERR  DEC 1 
IERMS DEC 5 
      ASC 3,DALC
* 
      END DALOC 
                                                                                                                                                                                                                                                              