ASMB,L
      HED STRING PACK ROUTINE 
      NAM PAK,7 92425-16037 REV.1841 780927 
* 
*-------------------------------------------------------------
* 
* 
*     F. WARREN         17MAY76    REV. A 
* 
*     "C" COPYRIGHT HEWLETT-PACKARD COMPANY 1976. 
*     ALL RIGHTS RESERVED.  NO PART OF THIS PROGRAM 
*     MAY BE PHOTOCOPIED, REPRODUCED OR TRANSLATED
*     TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR 
*     WRITTEN CONSENT OF THE HEWLETT-PACKARD COMPANY. 
* 
*-------------------------------------------------------------
* 
* 
* 
      ENT PAK,BUFP
* 
* 
* 
****************************************************
* 
*       STRING PACK ROUTINE 
* 
*       ADELE M. GADOL
* 
*       8/31/73 (REV.A) 
* 
****************************************************
* 
* 
* 
*     *****  EXTERNAL SYMBOLS  *****
* 
* 
* 
* 
*  THE FOLLOWING ROUTINE PACKS A CHARACTER INTO A BUFFER
*  ACCORDING TO THE POINTER BUFP WITHOUT ALTERING 
*  ANYTHING ELSE IN THE BUFFER.  THE ROUTINE UPDATES BUFP 
*  SO THAT A PACKED ASCII BUFFER MAY BE WRITTEN BY
*  SUCCESSIVE CALLS TO PAK.  BUFP CONTAINS THE ADDRESS
*  OF THE WORD TO PACK INTO; THE SIGN BIT, IF SET,
*  INDICATES A PACK INTO THE LOW ORDER BITS OF THE WORD.
* 
*  CALLING SEQUENCE:  LDA VALUE FOR BUFP
*                     STA BUFP
*                     LDA CHARACTER 
*                     JSB PAK 
*                     NORMAL RETURN 
* 
* 
* 
CHAR  BSS 1 
BUFP  BSS 1 
* 
PAK   NOP 
      LDB BUFP
      CLE 
      ELB,RBR 
      SEZ,RSS 
      ALF,ALF 
      STA CHAR
      LDA 1,I 
      SEZ 
      ALF,ALF 
      AND B177
      SEZ 
      ALF,ALF 
      XOR CHAR
      STA 1,I 
      SEZ,CME 
      INB,RSS 
      ELB,RBR 
      STB BUFP
      JMP PAK,I 
B177  OCT 177 
* 
      END 
                                                                                                                                                                                                                                        