ASMB,R,Q,C
      NAM BSTAT,7 92076-1X016  REV 2001  791207 92076-12001 
* 
      ENT BSTAT 
* 
      EXT SRQ.T,.ENTR,PNAME,IMESS 
* 
********************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS       *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,        *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT  *
*  * THE PROIR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.         *
********************************************************************
* 
*     NAME:   BSTAT 
*     RELOC:  PART OF 92076-12001 
*     SOURCE: 92076-18016 
*     PGMR:   T.A.L.
* 
* 
A     EQU 0 
B     EQU 1 
* 
CPAR1 BSS 1 
CPAR2 BSS 1 
CPAR3 BSS 1 
* 
BSTAT NOP 
      JSB .ENTR 
       DEF CPAR1
      LDA CPAR1,I   LOAD TRAP NUMBER
      STA TRAP      SAVE IT 
      CMA,SSA,INA   TRAP #'S 1-16 
      SZA,RSS       ARE LEGAL 
      JMP LOSE      ZERO OR NEG. LOSES
      ADA .16 
      SSA 
      JMP LOSE      GT 16 LOSES 
      LDB SRQ.T     GET SRQ.T ADDRESS 
      LDA TRAP      GET TRAP #
      ADA M1        SUBTRACT ONE
      STA TRAP
      RAL           INDEX BY TRAP # 
      ADA TRAP       INTO ARV.L 
      ADB A          TABLE. 
      INB           INDEX TO "VALUE" ADDR.
      LDA B,I       GET 'VALUE' FROM ARV.L TABLE
      STA CPAR2,I   RETURN 'VALUE'
      INB           INDEX TO 'STATUS' ADDR. 
      LDA B,I       GET 'STATUS' FROM ARV.L TABLE 
      STA CPAR3,I   RETURN 'STATUS' 
      JMP BSTAT,I   RETURN
* 
.16   DEC 16
M1    DEC -1
TRAP  BSS 1 
* 
LOSE  JSB PNAME 
       DEF *+2
       DEF MSGA+6   GET PROGRAM NAME
      JSB IMESS 
       DEF *+4
       DEF .2       WRITE 
       DEF MSGA     "ILL RQ-HPIB" 
       DEF .13      MESSAGE 
* 
      JMP BSTAT,I   RETURN
* 
.2    DEC 2 
.13   DEC 13
      SUP 
MSGA  ASC 13,ILL RQ-HPIB XXXXXXABORTED
* 
      END 
                                                                                                        