ASMB,Q,C
*     NAME: .XLA
*     SOURCE: 92071-18331 
*     RELOC:  92071-16331 
*     PGMR:   DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .XLA,6  92071-1X331 REV.2041  800416
* 
      ENT .XLA
      EXT .A.,.B.,.ZPRV,.XLD
* 
A     EQU 0 
B     EQU 1 
* 
.XLA  NOP 
      JSB .ZPRV 
      DEF EXIT
      STB .B.       SAVE B
      LDB .XLA,I    GET THE UNRESOLVED ADDRESS
      ISZ .XLA      ADJUST RETURN 
* 
* CLEAR INDIRECT BIT AND SKIP THE 
* NEXT INSTRUCTION IF ALREADY CLEAR 
* 
BACK  SSB 
      JMP RESLV 
* 
* THE MAPPING HARDWARE CAN NOT DEAL WITH THE B=0CASE. 
* THE B=1 CASE IS NOT HANDLED PROPERLY EITHER, BUT
* ITS EFFECTS ARE NOT AS CRITICAL 
* 
      SZB,RSS       B RESOLVE TO ZERO 
      JMP BADB
* 
      JSB .XLD      GET DATA (B HAS NO INDIRECTS) 
      DEF B,I 
RSTB  LDB .B.       RESTORE B 
EXIT  JMP .XLA,I
      DEF .XLA
* 
RESLV ELB,CLE,ERB   CHASE INDIRECT ONE LEVEL
      STB .A.       SAVE IN CASE IT WAS A REG REF 
      LDB .B. 
      LDB .A.,I 
      JMP BACK
* 
BADB  LDA B,I       DO LOCAL VERSION IN B=1 CASE
      JMP RSTB      GO RESTORE ORIGINAL B AND EXIT
      END 
                                                                                                                                                                                                                                        