ASMB,R,Q,C
*     NAME:   .MWW
*     SOURCE: 16328 
*     RELOC: 18328
*     PGMR:   DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .MWW,6 92071-1X328  REV.2041 800730 
      ENT .MWW
      EXT .X.,.ZPRV,.XLD,.XST 
A     EQU 0 
B     EQU 1 
* 
.MWW  NOP 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      STA .A        SAVE A-REG (SOURCE) 
      STB .B        SAVE B REG (DESTINATION)
      LDA .X.       GET THE COUNT 
      SZA,RSS       (DONT USE 'CMA,INA,SZA,RSS' - CHANGES E)
      JMP OUT       SKIP MOVE IF ZERO COUNT 
      CMA,INA       NEGATE FOR ISZ
      STA .X. 
* 
LOOP  JSB .XLD      GET WORD
.A    NOP           SHOULD BE NO INDIRECTS HERE 
      JSB .XST      MOVE THE WORD 
.B    NOP           SHOULD BE NO INDIRECTS HERE 
      ISZ .B        STEP DESTINATION
      ISZ .A        SOURCE
      ISZ .X.       DONE IF ZERO
      JMP LOOP      IF NOT DONE LOOP
* 
OUT   LDA .A        PUT NEXT LOC IN A 
      LDB .B
EXIT  JMP .MWW,I    AND RETURN
      DEF .MWW
* 
      END 
                                                                                                  