ASMB,R,Q,C
*     NAME:   .MWF
*     SOURCE: 92071-18326 
*     RELOC: 92071-16326
*     PGMR:   DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .MWF,6  92071-1X326  REV.2041  800730 
      ENT .MWF
      EXT .ZPRV,.XLD,.X.
A     EQU 0 
B     EQU 1 
* 
.MWF  NOP 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      STA .A        SAVE A AND B REG
      STB .B        (DESTINATION) 
      LDA .X.       GET THE COUNT 
      SZA,RSS       (DONT USE 'CMA,INA,SZA,RSS' - CHANGES E)
      JMP OUT       SKIP MOVE IF ZERO COUNT 
      CMA,INA       NEGATE COUNT FOR ISZ
      STA .X. 
* 
LOOP  JSB .XLD      GET WORD
.A    NOP           SHOULD BE NO INDIRECTS HERE 
      STA .B,I      MOVE THE WORD 
      ISZ .B        STEP DESTINATION
      ISZ .A        SOURCE
      ISZ .X.       DONE WHEN ZERO
      JMP LOOP      IF NOT DONE LOOP
* 
OUT   LDA .A        PUT NEXT LOC IN A 
      LDB .B
EXIT  JMP .MWF,I    AND RETURN
      DEF .MWF
* 
.B    NOP 
      END 
                                                                                                                                      