ASMB,R,Q,C
*     NAME:   PRTN
*     SOURCE: 92071-18211 
*     RELOC:  92071-1X211 
*     PGMR:   HLC,DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM PRTN,6  92071-1X211  REV.2041  800409 
      ENT PRTN,PRTM 
* 
      EXT $LIBR,$N5.F,$IDSZ 
      EXT $IDA,$XQT,$PAS5,$LIBX 
      EXT .XLA,.XLB,.XCB,$SJS1
* 
* 
A     EQU 0 
B     EQU 1 
* 
* 
PRTN  NOP           RETURN 5 PARAMETERS TO FATHER 
      JSB $LIBR     TURN OFF MEMORY PROTECT 
      NOP 
      DLD PRTN,I
      STA PRTN      RETURN ADDRESS
      CLA 
INDIR RBL,CLE,SLB,ERB CLEAR INDIRECT REFERENCES 
      LDB B,I 
      RBL,CLE,SLB,ERB 
      JMP *-2 
      ADB A         (FOR PRTM)
      STB FROM      SOURCE ADDRESS
      JSB .XLA      GET ID15
      DEF $N5.F 
      JSB .XLA
      DEF A,I 
      AND =B377     MASK CHAR 
      SZA,RSS 
      JMP EXIT      NO FATHER 
      ADA =D-1
      JSB .XLB
      DEF $IDSZ 
      MPY B         GET FATHER'S ID SEG ADDRESS 
      JSB .XLB
      DEF $IDA
      ADA B 
      STA PRTM
      ADA =D15
      JSB .XLA      FATHER'S STATUS 
      DEF A,I 
      AND =B77
      XOR =B3 
      JSB .XLB      GET WORD 1 OF ID
      DEF PRTM,I
      JSB .XCB      WAITING FOR CALLING PROGRAM?
      DEF $XQT
      SZA 
      JMP EXIT      NO
* 
      LDB PRTM
      JSB $SJS1     PASS PARAMETERS TO FATHER 
      DEF $PAS5 
FROM  NOP 
EXIT  JSB $LIBX     RESTORE MEMORY PROTECT
      DEF PRTN
* 
* 
PRTM  NOP           RETURN 4 PARAMETERS TO FATHER 
      JSB $LIBR 
      NOP 
      DLD PRTM,I
      STA PRTN      SAVE RETURN ADDRESS 
      CCA 
      JMP INDIR     JUMP INTO PRTN SUBROUTINE 
* 
      END 
                                                                                                                                                                                                                                