ASMB,R,L,C
      HED (FMGR) PAR..: COMMAND ENTRY AND PARSE CONTROL 
*     NAME:   PAR.. 
*     SOURCE: 92071-18200 
*     RELOC:  92071-16200 
*     PGMR:   G.A.A.
*     MOD:    M.L.K., E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM PAR..,7 92071-1X200 REV.2041 800728 
* 
      ENT PAR.. 
* 
      EXT .PARS, REA.C, MSS., ECHO
      EXT U.CMD, NO.RD, INT., ECHF., CUSE., CAD., SVCOD 
      EXT .ENTR, IFBRK
      SUP 
      SKP 
* 
*     ENTRY 
* 
PAR.. NOP          READ AND PARSE ENTRY POINT 
      JSB .ENTR 
      DEF PAR..    FETCH RETURN ADDRESS 
* 
      JSB IFBRK     CHECK FOR BREAK PENDING 
      DEF *+1 
      SZA,RSS       IF NO BREAK 
      JMP PAR1      SKIP MESSAGE
* 
      JSB MSS.      ELSE SEND THE BREAK MESSAGE 
      DEF *+2          AND TRANSFER TO LOG DEVICE 
      DEF ZERO
* 
PAR1  LDA NO.RD    GET NO-READ FLAG 
      SZA          IF FLAG ALREADY SET
      JMP PAR2      THEN BYPASS THE READ CALL 
* 
      JSB REA.C    READ A COMMAND FROM TERMINAL 
      DEF *+1 
* 
      JSB .PARS    PARSE THE
      DEF *+1       COMMAND 
* 
      LDA SVCOD    GET SEVERITY CODE
      SZA          IF SET,
      JMP PAR..,I   THEN RETURN 
* 
      LDA U.CMD    GET THE ASCII COMMAND
      CPA "SV      IF SV COMMAND, 
      JMP PAR..,I   THEN RETURN (LET SV DO THE ECHO)
* 
      CCA          SET TO ECHO COMMAND
      STA ECHF. 
      JSB ECHO     ECHO THE COMMAND 
      DEF *+1 
* 
      JMP PAR..,I   AND RETURN
* 
PAR2  CLB          CLEAR THE NO READ FLAG 
      STB NO.RD 
      SSA,RSS      IF TRANSFER COMMAND
      JMP TRLD
* 
      LDA INT.     GET INTERACTIVE FLAG 
      STA TMPM      SAVE FOR NOW
      CLA,INA      SET FOR INTERACTIVE INPUT
      STA INT.      SAVE FOR NOW
* 
      JSB .PARS    PARSE THE COMMAND
      DEF *+1 
* 
      LDA TMPM     RESTORE THE
      STA INT.      INTERACTIVE FLAG
      JMP PAR..,I    AND RETURN 
* 
TRLD  LDA TRSEG    GET TR SEGMENT NAME
      STA CUSE.    SAVE 
      LDA .3
      STA CAD.
      JMP PAR..,I  RETURN 
      SKP 
* 
*     STORAGE AREA
* 
ZERO  NOP 
.3    DEC 3 
* 
"SV   ASC 1,SV
TRSEG ASC 1,1 
* 
TMPM  NOP 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                                                                                                                                                                                      