ASMB,R,L,C
      HED (FMP) CV.RB: CONVERT TRACK,SECTOR TO RELATIVE BLOCK 
*     NAME:   CV.RB 
*     SOURCE: 92071-18195 
*     RELOC:  92071-16195 
*     PGMR:   E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM CV.RB,7 92071-1X195 REV.2041 800331 
* 
      ENT CV.RB 
* 
      EXT F.DCB, F.SIZ, F.S/T, F.TR2, F.SC2 
      EXT F.TR3, F.SC3, F.EXN, F.BFP
      SUP 
      SKP 
* 
*     DESCRIPTION 
* 
*     CV.RB CONVERTS A TRACK, SECTOR ADDRESS FROM A USER
*          DCB INTO A RELATIVE BLOCK ADDRESS
* 
*     THE CALLING SEQUENCE IS:
* 
*     JSB CV.RB 
*     <A = RELATIVE BLOCK; B = WORD OFFSET> 
      SKP 
* 
*     ENTRY 
* 
CV.RB NOP 
* 
      LDA F.DCB,I   GET DCB ADDRESS 
      ADA .16 
      CMA,INA 
      ADA F.BFP,I   GET BUFFER WORD OFFSET
      CLB 
      DIV .128      ISOLATE WORD OFFSET AND BLOCK OFFSET
      STA IRB        SAVE BLOCK PORTION 
      STB IOFF       SAVE WORD PORTION
* 
      LDA F.SIZ,I   GET FILE EXTENT SIZE
      ARS            CONVERT TO BLOCKS
      MPY F.EXN,I   MULTIPLY BY CURRENT EXTENT
      ADA IRB       ADD TO TOTAL
      STA IRB        SAVE AGAIN 
* 
      LDA F.TR2,I   GET STARTING TRACK
      CMA,INA 
      ADA F.TR3,I   SUBTRACT FROM CURRENT TRACK 
      MPY F.S/T,I   MULTIPLY BY SECTORS / TRACK 
      LDB F.SC2,I   GET STARTING SECTOR 
      CMB,INB 
      ADB F.SC3,I   SUBTRACT FROM CURRENT SECTOR
      ADA B         ADD TO TRACK PORTION
      ARS            CONVERT TO BLOCKS
      ADA IRB       ADD TO TOTAL
      LDB IOFF      GET WORD OFFSET 
* 
      JMP CV.RB,I   RETURN
* 
*     STORAGE AREA
* 
.16   DEC 16
.128  DEC 128 
* 
IRB   NOP           RELATIVE BLOCK NUMBER 
IOFF  NOP           RELATIVE WORD OFFSET
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                                                                                                            