ASMB,R,Q,C
*     NAME:   .MVW
*     SOURCE: 92071-18180 
*     RELOC:  92071-1X180 
*     PGMR:   HLC,DJN 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .MVW,6  92071-1X180  REV.2041  800730 
      ENT .MVW
      EXT .ZPRV 
A     EQU 0 
B     EQU 1 
* 
.MVW  NOP 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      STA .A        SAVE A-REG
      LDA .MVW,I    MICRO CODE MOVE REPLACEMENT 
      LDA A,I       GET THE COUNT 
      ISZ .MVW      STEP TO NOP (NOP IS RETURN) 
      SZA,RSS       (DONT USE 'CMA,INA,SZA,RSS' - CHANGES E)
      JMP OUT       SKIP MOVE IF ZERO COUNT 
      CMA,INA 
* 
      STA COUNT     SET COUNTER 
LOOP  LDA .A,I      GET WORD
      STA B,I       SET IN DESTINATION
      ISZ B         STEP DESTINATION (INB COULD SET O)
      ISZ .A        SOURCE
      ISZ COUNT     AND COUNT 
      JMP LOOP      IF NOT DONE LOOP
* 
OUT   LDA .A        PUT NEXT LOC IN A 
EXIT  JMP .MVW,I    AND RETURN
      DEF .MVW
* 
.A    NOP 
COUNT NOP 
      END 
                                                                                                                        