ASMB,R,Q,C
*     NAME:   XCMND 
*     SOURCE: 92071-18152 
*     RELOC:  92071-16152 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM XCMND,0  92071-16152  REV.2041  800414
      ENT $BRRQ,$DNRQ,$GORQ,$PRRQ,$SSRQ 
      ENT $$XCM,$.XCM 
* 
      EXT $FIND,$XEQ,$LUDV,$IODN
      EXT $LIST,$WORK,$PRAM,$P2 
      EXT $XQC,$PB,$INER,$WRKS
      EXT $LUTA,$DV1
* 
A     EQU 0 
B     EQU 1 
* 
      HED  BREAK COMMAND (BR) 
* 
* 
$BRRQ EQU *         SET BREAK BIT 
      JSB $FIND     FIND ID SEGMENT 
      LDA $WRKS,I 
      IOR =B10000 
      STA $WRKS,I   SET BREAK BIT 
      JMP $XEQ
* 
* 
      HED  DOWN COMMAND (DN)
$DNRQ JSB $LUDV     FIND DVT ADDRESS IN LU TABLE
      LDA $DV1
      CPA $LUTA,I 
      JMP $INER     ILLEGAL TO DOWN LU 1
      CCE 
      JSB $IODN     SET DEVICE DOWN 
      JMP $XEQ
* 
* 
      HED  GO COMMAND (GO)
$GORQ EQU *         RESUME PROGRAM
      JSB $FIND     FIND ID SEGMENT 
      CPA B6
      JMP OP        OPERATOR SUSPENDED
      CPA =B7 
      JMP PAUSE     PAUSED
      LDA $WRKS,I 
      AND =B177577  MAKE SURE SS BIT IS CLEAR 
      STA $WRKS,I 
      JMP $XEQ
* 
OP    JSB $LIST     RESUME IT 
B60   OCT 60
      JMP $XEQ
* 
PAUSE JSB $LIST     RESUME IT 
      OCT 60
      LDB $WORK 
      JSB $PRAM     PASS ANY PARAMETERS 
      DEF $P2,I 
      JMP $XQC      CONTINUE AS FOR 'XQ' COMMAND
* 
* 
      HED  PROGRAM PRIORITY COMMAND (PR)
$PRRQ JSB $FIND     FIND ID SEGMENT 
      LDA $PB+9     NEW PRIORITY
      SZA 
      SSA 
      JMP $INER     NEGATIVE ILLEGAL
      LDB $WORK 
      JSB $LIST     RE-LINK BY NEW PRIORITY 
      OCT -1
      JMP $XEQ
* 
* 
      HED SUSPEND COMMAND (SS)
$SSRQ EQU *         SUSPEND PROGRAM 
      JSB $FIND     FIND ID SEGMENT 
      CPA B6
      JMP $XEQ      ALREADY SUSPENDED 
      CPA B60 
      JMP SUSP      SCHEDULED, SO SUSPEND IT
      LDA $WRKS,I 
      IOR =B200     SET SS BIT
      STA $WRKS,I 
      JMP $XEQ
* 
SUSP  JSB $LIST     PUT IN OP SUSPEND STATE 
B6    OCT 6 
      JMP $XEQ
* 
* 
* 
$$XCM EQU *         STANDARD MODULE 
$.XCM DEC 0         STANDARD MODULE 
      END 
                                                                                                                                                                                                                            