ASMB,R,L,C
      HED (FMP) GTOPN: GET PROGRAM'S OPEN FLAG
*     NAME:   GTOPN 
*     SOURCE: 92071-18060 
*     RELOC:  92071-16060 
*     PGMR:   M.L.K.
*     MOD:    E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM GTOPN,7 92071-1X060 REV.2041 800402 
* 
      ENT GTOPN 
* 
      EXT .XLA, .XLB
      EXT $IDA, $IDSZ, $XQT, $CPU 
      SUP 
      SKP 
* 
*     DESCRIPTION 
* 
*     THIS ROUTINE CALCULATES THE CURRENT OPEN FLAG FOR 
*     FMGR AND FMP.  THE FORMAT OF THE OPEN FLAG IS:
* 
*     ------------------------------------------------- 
*     !  !   SEQ#    !  CPU#  !     ID SEGMENT #      ! 
*     ------------------------------------------------- 
*      15 14       11 10     8  7                    0
* 
      SKP 
* 
*     ENTRY 
* 
GTOPN NOP 
      ISZ GTOPN     SET UP RETURN ADDRESS 
      STB SAVB      SAVE B REGISTER 
* 
      JSB .XLA      GET START OF
      DEF $IDA+0     ID SEQMENTS
      CMA,INA         AND NEGATE
* 
      JSB .XLB      GET CURRENT 
      DEF $XQT+0     ADDRESS
      ADA B           ADD TO START GIVING OFFSET
* 
      JSB .XLB      GET ID SIZE 
      DEF $IDSZ+0 
      STB TEMP       AND SAVE FOR DIV 
* 
      CLB           CLEAR FOR DIVIDE
      DIV TEMP      DIVIDE BY ID SIZE FOR ID# 
      INA            ADD ONE SO NUMBERED 1 TO N 
      STA B           AND SAVE TEMPORARILY
* 
      JSB .XLA      GET CPU NUMBER
      DEF $CPU+0
      AND B7         TRUNCATE TO 3 BITS 
      ALF,ALF         MOVE TO BITS 8 - 10 
      ADB A            ADD TO OPEN FLAG 
* 
      JSB .XLA      GET CURRENT ID AGAIN
      DEF $XQT+0
      ADA .28        ADD OFFSET TO SEQUENCE NUMBER
* 
      JSB .XLA      GET SEQUENCE NUMBER 
      DEF A,I 
      AND B170K      ISOLATE SEQUENCE COUNT 
      RAR             MOVE TO BITS 11 - 14
      ADA B            ADD REST OF OPEN FLAG
* 
      LDB SAVB      RESTORE B REGISTER
      JMP GTOPN,I    AND RETURN 
      SKP 
* 
*     STORAGE AREA
* 
.28   DEC 28
* 
B7    OCT 7 
B170K OCT 170000
* 
SAVB  NOP           STORAGE FOR B-REG 
TEMP  NOP           TEMPORARY STORAGE 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                                                                                                                                                                                                                                        