ASMB,R,L,C
      HED (FMGR) MC.DC: MOUNT AND DISMOUNT DISC CARTRIDGE 
*     NAME:   MC.DC 
*     SOURCE: 92071-18025 
*     RELOC:  92071-16025 
*     PGMR:   G.L.M.
*     MOD:    M.L.K., E.D.B.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM MC.DC,7 92071-1X025 REV.2041 800630 
* 
      ENT MC.., DC..
* 
      EXT CRMC, CRDC
      EXT BUF.
      EXT PR.IT, MSS., SY.TR
      EXT .ENTR 
      SUP 
      SKP 
* 
*     MOUNT SUBROUTINE
* 
N     NOP 
LIS   NOP 
ER    NOP 
* 
MC..  NOP 
      JSB .ENTR     GET PARAMETERS
      DEF N 
* 
      ISZ LIS       BUMP PARAMETER LIST TO CARTRIDGE REFERENCE
      LDA LIS       CALCULATE ADDRESS OF LAST TRACK PARAMETER 
      ADA .4
      STA LIS5       AND SAVE FOR CALL
* 
      JSB CRMC      ATTEMPT TO MOUNT THE CARTRIDGE
      DEF *+3 
      DEF LIS,I 
      DEF LIS5,I
* 
      STA ER,I      SAVE ERROR CODE 
      JMP MC..,I     AND EXIT 
      SKP 
* 
*     DISMOUNT SUBROUTINE 
* 
NN    NOP 
NLIS  NOP 
NER   NOP 
* 
DC..  NOP 
      JSB .ENTR     GET PARAMETER LIST
      DEF NN
* 
      ISZ NLIS      BUMP TO FIRST PARAMETER 
      JSB CRDC      ATTEMPT TO DISMOUNT CARTRIDGE 
      DEF *+2 
      DEF NLIS,I
* 
      CPA N103      IF CORRUPT DIRECTORY
      JMP EXIT       THEN EXIT (OK) 
* 
      CPA .38       IF CANNOT REMOVE CARTRIDGE
      RSS            THEN CONTINUE
      JMP EREX       ELSE EXIT
* 
*     DETERMINE ACTIVE FILES
* 
      JSB SY.TR     CALL FOR ACTIVE PROGRAMS
      DEF *+6 
      DEF NLIS,I    DISC ID 
      DEF BUF.      USE OUTPUT BUFFER 
      DEF .128      USE 128 WORDS 
      DEF DUM1
      DEF DUM2
* 
      JSB MSS.      GO PRINT ERROR
      DEF *+2 
      DEF .38       SYSTEM USING DISC 
* 
      JSB PR.IT     PRINT LIST OF CONFLICTING PROGRAMS
      DEF *+3 
      DEF BUF.
      DEF .128
* 
EXIT  CLA           NO ERROR INTENDED 
* 
EREX  STA NER,I     SAVE ERROR CODE FOR USER
      JMP DC..,I
      SKP 
* 
*     STORAGE AREA
* 
.4    DEC 4 
.38   DEC 38
.128  DEC 128 
* 
N103  DEC -103
* 
LIS5  NOP           LAST TRACK PARAMETER ADDRESS
DUM1  NOP 
DUM2  NOP 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
* 
      END 
                                                                                                                                                                                                                    