ASMB,R,Q,C
*     NAME:   IFTAP 
*     SOURCE: 92070-18260 
*     RELOC:  92070-1X260 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM IFTAP,7  92070-1X260  REV.1941  790607
      ENT IFTAP 
      EXT EXEC
* 
* 
*     PURPOSE:  TO DETERMINE IF A DEVICE IS A MAGNETIC TAPE 
*               (OR CARTRIDGE TAPE).
* 
*     CALLING SEQUENCE: 
*       I=IFTAP(LU) 
*         I: -1 IF MAGNETIC TAPE DEVICE 
*             0 IF NOT MAGNETIC TAPE DEVICE 
* 
*    OR 
* 
*       IF(IFTAP(LU))10,20
*         GOES TO 10 IF MAGNETIC TAPE DEVICE  
*         GOES TO 20 IF NOT MAGNETIC TAPE DEVICE  
* 
A     EQU 0 
B     EQU 1 
* 
* 
IFTAP NOP 
      DLD IFTAP,I 
      LDB B,I 
      STB LU        LU NUMBER 
      STA IFTAP     RETURN ADDRESS
* 
      JSB EXEC      STATUS REQUEST
      DEF *+4 
      DEF D13NA     NO ABORT
      DEF LU
      DEF TYPE
      JMP NO        NOT A VALID LU
      LDA TYPE
      AND =B37400 
      STA B         DEVICE TYPE IN B (HIGH BYTE)
      AND =B34000 
      CPA =B10000 
      CCA,RSS       FIRST DIGIT=2, MAGNETIC TAPE
NO    CLA 
      JMP IFTAP,I   EXIT
* 
TYPE  NOP 
LU    NOP 
D13NA OCT 100015
* 
      END 
                                                                                                                                                                                        