ASMB,R,Q,C
*     NAME:   .CMW  
*     SOURCE: 92070-18230 
*     RELOC:  92070-1X230 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM .CMW,6  92070-1X230  REV.1941  790926 
      ENT .CMW
      EXT .ZPRV 
* 
A     EQU 0 
B     EQU 1 
* 
* 
.CMW  NOP           COMPARE WORDS 
      JSB .ZPRV     SHARABLE ROUTINE
      DEF EXIT
      STA .A.       SAVE A REGISTER 
      ERA,ALS 
      SOC 
      INA 
      STA .EO.      SAVE E AND O
* 
      LDA .CMW,I    ADDRESS OF COUNT
      ISZ .CMW
      LDA A,I       WORD COUNT
      SZA,RSS 
      JMP CMWEX     ZERO, EXIT
      ADA B 
      STA .B.       FINAL B REGISTER VALUE
* 
* 
* 
CMWLP LDA .A.,I 
      CPA B,I 
      INB,RSS 
      JMP LT.GT     DOES NOT COMPARE
      ISZ .A. 
      CPB .B.       CHECK FOR DONE
      JMP CMWEX 
      JMP CMWLP     NEXT
* 
* 
LT.GT ISZ .CMW      SKIP OVER ZERO WORD 
      ISZ .CMW      SKIP OVER NORMAL RETURN 
      CMA,INA 
      ADA B,I       SUBTRACT A FROM B 
      SSA 
      ISZ .CMW      A LARGER THAN B 
      LDB .B. 
* 
CMWEX LDA .EO.
      CLO           RESET OVERFLOW
      SLA,ELA 
      STO 
      LDA .A. 
EXIT  JMP .CMW,I
      DEF .CMW
* 
* 
.A.   NOP 
.B.   NOP 
.EO.  NOP 
      END 
                                                                                                                        