ASMB,R,Q,C
*     NAME:   PRTN  
*     SOURCE: 92070-18211 
*     RELOC:  92070-1X211 
*     PGMR:   HLC 
* 
* 
*  **************************************************************** 
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS      * 
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,       * 
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT * 
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.        * 
*  **************************************************************** 
* 
* 
      NAM PRTN,6  92070-1X211  REV.1941  790205 
      ENT PRTN,PRTM 
* 
      EXT $LIBR,$N5.F,$IDSZ 
      EXT $IDA,$XQT,$PRAM,$LIBX 
* 
* 
A     EQU 0 
B     EQU 1 
* 
* 
PRTN  NOP           RETURN 5 PARAMETERS TO FATHER 
      JSB $LIBR     TURN OFF MEMORY PROTECT 
      NOP 
      DLD PRTN,I
      STA PRTN      RETURN ADDRESS
      CLA 
INDIR RBL,CLE,SLB,ERB CLEAR INDIRECT REFERENCES 
      LDB B,I 
      RBL,CLE,SLB,ERB 
      JMP *-2 
      ADB A         (FOR PRTM)
      STB FROM      SOURCE ADDRESS
      LDA $N5.F,I 
      AND =B377 
      SZA,RSS 
      JMP EXIT      NO FATHER 
      ADA =D-1
      MPY $IDSZ     GET FATHER'S ID SEG ADDRESS 
      ADA $IDA
      STA PRTM
      ADA =D15
      LDA A,I       FATHER'S STATUS 
      AND =B77
      XOR =B3 
      LDB PRTM,I
      CPB $XQT      WAITING FOR CALLING PROGRAM?
      SZA 
      JMP EXIT      NO
* 
      LDB PRTM
      JSB $PRAM     PASS PARAMETERS TO FATHER 
FROM  NOP 
EXIT  JSB $LIBX     RESTORE MEMORY PROTECT
      DEF PRTN
* 
* 
PRTM  NOP           RETURN 4 PARAMETERS TO FATHER 
      JSB $LIBR 
      NOP 
      DLD PRTM,I
      STA PRTN      SAVE RETURN ADDRESS 
      CCA 
      JMP INDIR     JUMP INTO PRTN SUBROUTINE 
* 
      END 
                                                                                                                                                                                                                                    