ASMB,R,L,C
*     NAME:   DRKEI 
*     SOURCE: 92070-18131 
*     RELOC:  92070-16131 
*     PGMR:   D.J.W.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM DRKEI,7  92070-1X131  REV.1941  790711
* 
* 
*  DRKEI OUTPUTS A MESSAGE TO THE LIST DEVICE USING SUBROUTINE DRKEY. 
*  IF THE COMMAND DEVICE IS INTERACTIVE AND NOT THE SAME AS THE LIST
*  DEVICE THEN THE SAME MESSAGE IS OUTPUT TO THE INTERACTIVE COMMAND
*  DEVICE ALSO. 
* 
*  CALLING SEQUENCE:  A-REG = MESSAGE ADDRESS 
*                     B-REG = MESSAGE LENGTH IN CHARACTERS
*                     JSB DRKEI 
* 
*  ON RETURN:         A-REG = FMP ERROR CODE FROM LIST WRITE
* 
      ENT DRKEI 
      EXT CDCB,DRKEY,IN.TR,LADCB,LDCB 
* 
A     EQU 0 
B     EQU 1 
* 
DRKEI NOP 
      DST TEMPS     SAVE A AND B RESIGTERS IN TEMPS 
      LDA IN.TR     COMMAND INTERACTIVE AND NOT LIST DEVICE ? 
      SLA,RSS 
      JMP NOXCG     NO, NO EXCHANGE OF DCB'S
* 
      LDA ACDC      ADDRESS OF COMMAND DCB
      STA LADCB     SET FOR DRKEY OUTPUT
      DLD TEMPS     LOAD THE TEMPORARIES
      JSB DRKEY     CALL DRKEY TO OUTPUT THE MESSAGE
      LDB ALDC      RESET ADDRESS OF LIST DCB 
      STB LADCB     BACK FOR DRKEY
* 
NOXCG DLD TEMPS 
      JSB DRKEY     NOW OUTPUT TO LIST DEVICE 
      JMP DRKEI,I   AND RETURN TO CALLER
* 
TEMPS BSS 2           TEMPORARY VARIABLES 
ACDC  DEF CDCB+0    ADDRESS OF COMMAND DCB
ALDC  DEF LDCB+0    ADDRESS OF LIST DCB 
      END 
                                                                                                                                                                                                      