ASMB,R,L,C
*     NAME:   LDRER 
*     SOURCE: 92070-18122 
*     RELOC:  92070-1X122 
*     PGMR:   D.J.W.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1976.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM LDRER,7  92070-1X122  REV.1941  800228
* 
* 
*  LDRER OUTPUTS THE LOADER ERROR MNEUMONIC TO THE LIST DEVICE
*  OR COMMAND, IF INTERACTIVE.  ON RETURN THE A REGISTER IS 
*  RESTORED TO THE ERROR CODE.
* 
*    CHANGE 11/30/79
*  ADDED ERROR MESSAGE 'OV OUT' TO DECLARE THE CASE OF AN FMP 
*  -12 ERROR ON THE OUTPUT FILE.
* 
*  CALLING SEQUENCE:  A-REG = ERROR CODE
*                     JSB LDRER 
* 
*  ON RETURN:         A-REG = ERROR CODE
* 
      ENT LDRER 
      EXT SYOUT,MERR
* 
A     EQU 0 
B     EQU 1 
* 
LDRER NOP 
      STA TEMP
      MPY P3        CALCULATE OFFSET INTO LIST OF ERROR CODES 
      ADA EMESS     ADD STARTING ADDRESS OF LIST
      STA B         AND SAVE IN B-REG FOR SYOUT 
      STA MERR
      LDA P6        LENGTH OF MESSAGE IN CHARACTERS 
      JSB SYOUT     OUTPUT MESSAGE
      LDA TEMP
      JMP LDRER,I   AND RETURN
* 
TEMP  BSS 1 
EMESS DEF EMES
P3    DEC 3 
P6    DEC 6 
* 
*  ALL POSSIBLE LOADER ERROR CODES ARE LISTED BELOW.
* 
*                         MNEMONIC  CODE   EXPLANATION
      ASC 3,RF EMA   -11   ILLEGAL REFERENCE TO EMA ARRAY 
      ASC 3,ML EMA   -10   MULTIPLE DECLARATION OF EMA
      ASC 3,IL REL   -9    ASSEMBLER PRODUCED ILLEGAL RECORD
      ASC 3,RE SEQ   -8    RECORD OUT OF SEQUENCE 
      ASC 3,DU ENT   -7    DUPLICATE ENTRY POINT
      ASC 3,CM BLK   -6    COMMON BLOCK ERROR 
      ASC 3,OV SYM   -5    SYMBOL TABLE OVERFLOW
      ASC 3,OV FIX   -4    FIXUP TABLE OVERFLOW 
      ASC 3,OV MEM   -3    MEMORY OVERFLOW
      ASC 3,IL REC   -2    ILLEGAL RECORD 
      ASC 3,CK SUM   -1    CHECKSUM ERROR 
EMES  ASC 3,IL PRM    0    ILLEGAL PARAMETER
      ASC 3,OV BSE    1    BASE PAGE OVERFLOW 
      ASC 3,TR ADD    2    NO TRANSFER ADDRESS
      ASC 3,IL SNP    3    ILLEGAL SNAPSHOT 
      ASC 3,LM LIB    4    NUMBER OF LIBRARIES EXCEEDED 
      ASC 3,IL BND    5    ILLEGAL PROGRAM OR BASE PAGE BOUND VALUE 
      ASC 3,NM SEG    6    NO SEGMENT SPECIFIED, BUT ONE WAS READ 
      ASC 3,UN EXT    7    UNDEFINED EXTERNALS, LOAD ABORTED
      ASC 3,DU PGM    8    DUPLICATE PROGRAM NAME 
      ASC 3,NO SEG    9    LOADER COULDN'T LOAD ITS OWN SEGMENTS
      ASC 3,OV OUT    10   FMP -12 ON THE OUTPUT FILE 
      ASC 3,IL IDX    11   BAD INDEX RECORD IN INDEXED FILE 
      END 
                                                                                                                                                                                                                      