ASMB,R,L,C
*     NAME:   TR.SC 
*     SOURCE: 92070-18107 
*     RELOC:  92070-16107 
*     PGMR:   M.L.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM TR.SC,7  92070-1X107  REV.1941  790709
* 
      SKP 
* 
      ENT TR.SC 
      EXT .ENTR,EXEC
      SUP 
* 
* 
DSLU  NOP           DISC LU PARAMETER 
NMTRK NOP           NUMBER OF TRACKS PARAMETER
NSC/T NOP           NUMBER OF SECT/TRACK PARAMETER
* 
TR.SC NOP 
      JSB .ENTR 
      DEF DSLU
* 
      LDA DSLU,I    GET DISC LU 
      IOR ZBIT      ADD IN MULTI BUFFER Z BIT 
      STA DSLU      SAVE FOR EXEC CALL
* 
      JSB EXEC      GET STATUS ON LU
      DEF ERRTN 
      DEF STCOD     NO-ABORT STATUS REQUEST 
      DEF DSLU      DISC LU WITH Z BIT SET
      DEF BUF       DUMMY 
      DEF BUF       DUMMY 
      DEF BUF       STORE 7 DRIVER PARAMETERS 
      DEF .7        INTO BUF
ERRTN JMP TR.SC,I   ERROR RETURN WITH A = ASCII OF ERROR
* 
      LDA TRKS      GET NUMBER OF TRACKS
      STA NMTRK,I   SAVE IN USER'S BUFFER 
      LDA SC/T      GET # SECTORS/TRACK AND MULTIPLY
      ALS           BY 2 FOR 64 WORD SECTORS
      STA NSC/T,I   SAVE IN USER'S BUFFER 
      CLA           A = 0 FOR SUCCESS 
      JMP TR.SC,I    - RETURN - 
* 
ZBIT  OCT 10000 
STCOD OCT 100015
.7    DEC 7 
* 
BUF   NOP           HPIB ADDRESS
      NOP           UNIT #
      NOP           STARTING HEAD 
      NOP           STARTING CYLINDER 
      NOP           # OF SPARES 
TRKS  NOP           NUMBER OF TRACKS
SC/T  NOP           NUMBER OF SECTORS/TRACK 
      END 
                                                                                                  