ASMB,R,L,C
*     NAME:   PR.IT 
*     SOURCE: 92070-18069 
*     RELOC:  92070-16069 
*     PGMR:   M.L.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM PR.IT,7  92070-1X069  REV.1941  790709
* 
* 
*     THIS ROUTINE PRINTS A LIST OF PROGRAM NAMES FROM
*     AN ARRAY OF POINTERS TO ID SEGEMENTS.  IT IS USED 
*     IN CONJUNCTON WITH SY.TR TO LIST ACTIVE SYSTEM PROGRAMS.
      SKP 
      ENT PR.IT 
      EXT CAM.O,.ENTR,EXEC
      SUP 
      SPC 3 
ARRAY NOP 
ASIZE NOP 
* 
PR.IT NOP 
      JSB .ENTR     SET UP PARAMETERS 
      DEF ARRAY 
* 
      LDA ASIZE,I   GET ARRAY SIZE
      CMA,INA       SET IT NEGATIVE 
      SSA,RSS       IF IT WAS NEGATIVE OR 0 
      CCA           SET IT TO -1
      STA ASIZE     NOW STORE IT
* 
LOOP  LDA ARRAY,I   GET THE NEXT ARRAY ENTRY
      SZA,RSS         IF IT IS 0, 
      JMP PR.IT,I     THEN EXIT 
* 
      SSA           IF IT'S NEGATIVE, IT'S SWAP 
      JMP SWAP        GO CHECK WHICH
      LDB N5        SET CHARACTER COUNT FOR EXEC
WRIT  STA BUF       STORE BUFFER ADDRESS
      STB COUNT     STORE LENGTH
      JSB EXEC      CALL THE SYSTEM TO WRITE OUT THE NAME 
      DEF *+5 
      DEF O2        WRITE 
      DEF CAM.O     TO LOG DEVICE 
BUF   DEF * 
      DEF COUNT 
* 
      ISZ ARRAY     INCREMENT TO NEXT ELEMENT 
      ISZ ASIZE     END OF ARRAY? 
      JMP LOOP      NO, WRITE NEXT
      JMP PR.IT,I   YES, EXIT 
* 
SWAP  LDA DSWPB     GET SWAP BUFFER ADDRESS 
      LDB .6        SET WORD COUNT
      JMP WRIT      GO WRITE IT 
* 
* 
O2    OCT 2 
N5    DEC -5
.6    DEC 6 
DSWPB DEF SWPBF 
SWPBF ASC 6,SWAP AREA 
* 
COUNT NOP 
* 
A     EQU 0 
B     EQU 1 
END   EQU * 
      END 
                                                                                                                                                                                                                  