ASMB,R,L,Z,C
*     NAME:   P.PAS 
*     SOURCE: 92070-18067 
*     RELOC:  92070-16067 
*     PGMR:   G.A.A.
*     MOD:    G.L.M 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM P.PAS,7  92070-1X067  REV.1941  790709
      ENT P.PAS 
* 
      HED P.PAS 
*  P.PAS IS USED TO SET UP ADDRESS OR TO MOVE 
*  INFORMATION FROM THE CALL AREA 
* 
*     CALLING SEQUENCE: 
* 
*     E=0     SET UP CALL AREA
*     E=1     MOVE FROM CALL AREA 
*     B=0     SET ADDRESSES ONLY
*     B=100000   MOVE PARAMETERS
*     A   =   ADDRESS OF OTHER AREA OR FIRST ADDRESS
* 
*     JSB P.PAS 
*     DEC -N        N= NO. OF WORDS TO BE SET UP
*     BSS N         CALL AREA BUFFER
*                   IF B IS 0, THIS WILL BE A 
*                   LIST OF ADDRESSES; IF B=100000, 
*                   THIS WILL BE THE WORDS AT THE 
*                   ADDRESS PROVIDED IN A.
* 
* 
P.PAS NOP 
      ADB LOAD      CONFIGURE THE LOAD
      STB NEXT      AND SET IT
      LDB P.PAS,I   GET THE COUNT 
      STB COUNT     AND SET 
      ISZ P.PAS     STEP TO PRAM AREA 
      LDB P.PAS     ADDRESS TO B
      SEZ           IF FROM 
      SWP           SWAP ADDRESSES
      STB DEST      SAVE THE DESTINATION ADDRESS
NEXT  LDB A         GET ADDRESS OR IF LDB A,I 
      STB DEST,I    A WORD - SET IF 
      ISZ DEST      STEP DESTINATION
      INA           STEP FROM 
      ISZ COUNT     STEP COUNT - DONE?
      JMP NEXT      NO; GET NEXT ONE
      SEZ           YES; EXIT TO
      JMP A,I       END OF CALL 
      JMP DEST,I    SEQUENCE
      SPC 5 
COUNT NOP 
DEST  NOP 
LOAD  LDB A 
TEST  NOP 
      SPC 2 
A     EQU 0 
B     EQU 1 
END EQU * 
      END 
                                                                                                                                                                                                                                        