ASMB,R,L,C
*     NAME:   CR.LU 
*     SOURCE: 92070-18056 
*     RELOC:  92070-16056 
*     PGMR:   M.L.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM CR.LU,7  92070-1X056  REV.1941  790709
* 
* 
*     THIS ROUTINE IS USED TO CONVERT A NEGATIVE LU OR A
*     POSITIVE CRN INTO THE CORRESPONDING DISC LU.  IF THE
*     REQUESTED LU OR CRN IS NOT FOUND, A=0 AND E=1 (FRETURN).
* 
      SKP 
      ENT CR.LU 
      EXT .ENTR,$CDIR 
      SPC 3 
CRNLU NOP 
* 
CR.LU NOP 
      JSB .ENTR     SET UP PARAMETER
      DEF CRNLU 
* 
      LDA CRNLU,I   GET CR/LU PASSED
      CCE,SZA,RSS   IS IT 0?  (SET FAILED EXIT) 
      JMP CR.LU,I   YES,EXIT
* 
      SSA           IS IT POSITIVE OR NEGATIVE? 
      JMP LU        NEGATIVE, MUST BE LU
      STA CRNLU     POSITIVE, IT'S A CRN
      LDA N2        SET TO BACKUP WHEN
      STA OFSET     CRN IS FOUND
      LDB .2        OFFSET INTO TABLE BY 2
* 
SERCH ADB DCDIR     GET ADDRESS OF FIRST CRN/LU 
LOOP  LDA B,I       GET CRN/LU
      SZA,RSS       END OF LIST?
      JMP CR.LU,I   YES, EXIT NOT FOUND 
* 
      CPA CRNLU     THIS THE ONE WE'RE LOOKING FOR? 
      JMP FOUND     YES, GO GET LU
      ADB .4        NO, TRY NEXT ONE
      JMP LOOP
* 
FOUND CLE           SET FOUND EXIT
      ADB OFSET     BACKUP IF NECESSARY 
      LDA B,I       GET LU
      JMP CR.LU,I     AND EXIT
* 
LU    CMA,INA       CONVERT TO POSITIVE 
      STA CRNLU       AND SAVE
      CLB           CLEAR FOR NO
      STB OFSET       OFFSET
      JMP SERCH     GO SEARCH CARTRIDGE LIST
* 
* 
N2    DEC -2
.2    DEC 2 
.4    DEC 4 
DCDIR DEF $CDIR+0 
* 
OFSET NOP 
A     EQU 0 
B     EQU 1 
END   EQU * 
      END 
                                                                                                                                                                                                                          