ASMB,R,L,C
*     NAME:   FSTAT 
*     SOURCE: 92070-18043 
*     RELOC:  92070-16043 
*     PGMR:   M.L.K.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
      NAM FSTAT,7  92070-1X043  REV.1941  790709
* 
      HED FSTAT 
      ENT FSTAT 
      EXT .ENTR,.MVW,$CDIR,$MDSP
* 
      SPC 3 
FSTAT NOP           DUMMY ENTRY POINT 
      LDA D125      GET DEFAULT LENGTH
      STA STAT      STORE TO TEST FOR PARAMETER SENT
      STA LEN       STORE HERE FOR DEFAULT
      LDA FSTAT 
      STA DSTAT 
      JMP DSTAT+1 
* 
* 
STAT  NOP 
LEN   NOP 
* 
DSTAT NOP 
      JSB .ENTR 
      DEF STAT
      LDA N10       PRESET ERROR
      LDB STAT      CHECK FOR ARRAY ADDRESS 
      CPB D125      SAME AS DEFAULT?
      JMP DSTAT,I   YES, ERROR -10, NOT ENOUGH PARAMETERS 
* 
      LDA DCDIR     GET ADDRESS OF START OF DIRECTORY 
      LDB $MDSP     GET END OF DIRECTORY ADDRESS
      CMA,INA       MAKE STARTING ADDRESS NEGATIVE
      ADB A         CALCULATE SIZE
      INB           ADD ONE FOR TERMINATION WORD
      LDA LEN,I     GET USER'S BUFFER LENGTH
      CMA,INA       SET A NEGATIVE
      ADA B         ADD TO DIRECTORY SIZE 
      SSA,RSS       USE WHICH SIZE? 
      LDB LEN,I     USE PASSED PARAMETER
      STB LENTH     STORE FOR CALL
* 
      LDA DCDIR     LOAD A SOURCE ADDRESS 
      LDB STAT      LOAD B DESTINATION ADDRESS
      JSB .MVW      CALL MOVE 
      DEF LENTH       WITH NUMBER OF PARAMETERS TO MOVE 
      NOP           (FOR COMPATIBILITY) 
* 
      CLA           SET NO ERROR
      JMP DSTAT,I 
      SKP 
N10   DEC -10 
D125  DEF .125
.125  DEC 125 
LENTH NOP 
DCDIR DEF $CDIR+0 
* 
A     EQU 0 
B     EQU 1 
* 
END   EQU * 
      END 
                                                                                                                                                                                                              