ASMB
      NAM CITA,7 92069-16174 REV.1912 770601
* 
* 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
* 
* 
*     SOURCE:    92069-18174
*     RELOC:     92069-16174
* 
* 
************************************************************* 
* 
      SPC 1 
      EXT .ENTR 
      ENT CITA
      SPC 1 
A     EQU 0 
B     EQU 1 
      SPC 1 
*     CALL CITA(INT,IA) 
* 
*         CONVERT AN INTEGER (INT) TO ITS 
*         DECIMAL EQUIVALENT IN ASCII 
*         FORMAT IN THE 3 WORD ARRAY (IA) 
      SPC 1 
INT   BSS 1 
IA    BSS 1 
CITA  NOP               ENTER AND 
      JSB .ENTR           GET ARGUMENT
      DEF INT             ADDRESSES 
      LDA TA            SET UP NUMBER TABLE 
      STA IPICK           POINTER 
      LDA INT,I         GET THE INTEGER 
      LDB MINUS         GENERATE
      SSA                 THE SIGN
      CMA,INA,RSS         AND THE 
      LDB BLANK           FIRST NUMBER
      JSB ONEN
      STB IA,I
      CLB               GENERATE
      JSB ONEN            THE NEXT
      BLF,BLF             TWO NUMBERS 
      JSB ONEN
      ISZ IA
      STB IA,I
      CLB               GENERATE
      JSB ONEN            THE LAST
      BLF,BLF             TWO NUMBERS 
      ADB =B60
      ADB A 
      ISZ IA
      STB IA,I
      JMP CITA,I
      SPC 1 
ONEN  NOP               ENTER CONVERSION ROUTINE
      ADB =B60
ON1   ADA IPICK,I 
      SSA 
      JMP ON2 
      INB 
      JMP ON1 
ON2   CMA,INA 
      ADA IPICK,I 
      CMA,INA 
      ISZ IPICK 
      JMP ONEN,I
      SPC 1 
TA    DEF NBUF
NBUF  DEC -10000
      DEC -1000 
      DEC -100
      DEC -10 
BLANK OCT 20000 
MINUS OCT 26400 
      SPC 1 
IPICK BSS 1 
      END 
                                                                                                                                                                                                                                          