ASMB
       NAM  WORKR,7 92069-16061 REV.1912 790208 
* 
* 
**************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS    *
* RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* PRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH-  *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.  *
**************************************************************
* 
* 
*     SOURCE:    92069-18101
*     RELOC:     92069-16060
* 
* 
************************************************************* 
* 
       ENT  INITX,WORKX 
       EXT  .ENTR,EXEC,.DMP,.DDI,.DDE,.DSBR 
FTRK   BSS  1           FIRST TRACK OF WORK AREA. 
SIZE   BSS  1           SECTORS PER TRACK 
JSECT  BSS  1           SECTORS PER BLOCK.
CONWD  BSS 1            DISC LU 
INITX  NOP
       JSB  .ENTR 
       DEF  FTRK
       LDA  FTRK,I
       STA  FTRK
       CLA
       LDB  SIZE,I
       DST  ISIZE 
       LDB  JSECT,I 
       ADB  JSECT,I 
       DST SECTR
       LDA CONWD,I  SET DISC
       IOR =B100      LOGICAL UNIT
       STA CONWD
       JMP  INITX,I 
* 
RORW   BSS  1           1=READ; 2=WRITE.
BUF    BSS  1           BUFFER ADDRESS. 
WORDS  BSS  1           POSITIVE NUMBER OF WORDS. 
BLKNO  BSS  1           BLOCK NUMBER. 
WORKX  NOP
       JSB  .ENTR 
        DEF  RORW 
       DLD  BLKNO,I     CONVERT BLOCK NUMBER TO 
       JSB  .DDE
       JSB  .DMP
        DEF SECTR 
       DST  TEMP
       JSB  .DDI     GET TRACK NUMBER 
        DEF ISIZE 
       STB  TRK 
* 
       JSB  .DMP     GET SECTOR NUMBER
        DEF ISIZE 
       JSB  .DSBR 
        DEF TEMP
       STB  SECT
* 
       LDA  TRK 
       ADA  FTRK
       STA  TRK 
* 
       JSB  EXEC        START TRANSFER TO/FROM
        DEF  *+7          THE WORK AREA.
        DEF  RORW,I 
        DEF  CONWD
        DEF  BUF,I
        DEF  WORDS,I
        DEF  TRK
        DEF  SECT 
* 
       JMP  WORKX,I 
* 
TRK    BSS  1 
SECT   BSS  1 
ISIZE  BSS 2
SECTR  BSS 2
TEMP   BSS 2
       END
                                                                                                                                                                                                                      