ASMB,R,L,C
* 
*     NAME:   RMPAR 
*     SOURCE: 92068-18025 
*     RELOC:  PART OF 92067-16268 AND 92067-16035 
*     PGMR:   R.A.G.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM RMPAR,7 92068-1X025 REV.2013 781106 
* 
*     GENERAL UTILITY ROUTINE TO LOAD OPERATOR
*         CONTROL PARAMETERS INTO A CALLERS BUFFER
*     OP SYSTEM SETS UP B-REG TO POINT TO ID SEGMENT TEMPS
*     FORTRAN CALLING SEQUENCE: 
*         DIMENSION IBUF(5) 
*         CALL RMPAR(IBUF)
*     ASSEMBLY LANGUAGE CALLING SEQUENCE
*         JSB RMPAR 
*         DEF  *+2
*         DEF  IBUF      WHERE IBUF IS BSS 5
*         (NORMAL RETURN) 
* 
* 
*     IN RTE-IV, THE PARAMETERS ARE IN THE SYSTEM MAP ONLY. 
* 
      ENT RMPAR 
* 
      EXT $OPSY 
XTEMP EQU 1721B 
* 
* 
RMPAR NOP 
      ISZ RMPAR 
      LDA RMPAR     GET P+2 ADDRESS 
      LDA A,I       GET POSSIBLE VALUE
      RAL,CLE,SLA,ERA 
      JMP *-2       GOT DIRECT YET? 
      STA TEMP1     SAVE AS POINTER TO IBUF 
      ISZ RMPAR 
      LDA $OPSY 
      CPA =D-9      IF RTE-IV 
      JMP RTEIV       LOAD FROM SYSTEM MAP
      LDA =D-5
      STA TEMP2 
RMPLP LDA B,I 
      STA TEMP1,I 
      INB 
      ISZ TEMP1 
      ISZ TEMP2 
      JMP RMPLP 
      JMP RMPAR,I 
* 
* 
RTEIV LDA XTEMP 
      LDB TEMP1 
      STX TEMP2     (SAVE & RESTORE X)
      LDX =D5 
      MWF           MOVE 5 WORDS FROM SYSTEM MAP
      LDX TEMP2 
      JMP RMPAR,I 
* 
TEMP1 NOP 
TEMP2 NOP 
A     EQU 0 
B     EQU 1B
      END 
* 
* 
                                                                                                                                              