ASMB,R,L,C
* 
*     NAME:   .LBT
*     SOURCE: 92068-18008 
*     RELOC:  PART OF 92067-16268 AND 92067-16035 
*     PGMR:   R.A.G.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1980.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM .LBT,6 92068-1X008 REV.2013 770518
      ENT .LBT
      EXT .ZPRV 
* THIS ROUTINE PROVIDES SOFTWARE SIMULATION OF THE LBT
* INSTRUCTION IN THE 21MX EXTENDED INSTRUCTION GROUP. 
B     EQU 1 
E.O   NOP 
CHAR  NOP 
* 
.LBT  NOP 
      JSB .ZPRV 
      DEF .LBTX 
      ERA,ALS 
      SOC 
      INA 
      STA E.O       SAVE E AND O REGISTERS
      CLE,ERB       SHIFT BYTE INDICATOR TO E 
      LDA B,I       WORD CONTAINING CHARACTER TO A. 
      SEZ,RSS       IF E=0, ROTATE TO GET THE CHAR- 
      ALF,ALF         ACTER IN A[7:0].
      AND =B377     MASK OUT EXTRANEOUS BITS. 
      STA CHAR      SAVE IT 
      ELB 
      INB           STEP TO NEXT BYTE 
      CLO 
      LDA E.O 
      SLA,ELA       RESTORE E AND O REGISTERS 
      STO 
      LDA CHAR
.LBTX JMP .LBT,I    RETURN WITH CHAR IN A.
      DEF .LBT
      END 
                                                                                                                  