ASMB,Q
      NAM XPRTY,7 92067-1X518 REV.2040 800717 
      ENT XPRTY 
* 
***************************************************************** 
*                                                               * 
*  (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS       * 
*  RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,        * 
*  REPRODUCED OR TRANSLATED TO ANOTHER PROGRAMMING LANGUAGE     * 
*  WITHOUT THE PRIOR WRITTEN CONSENT OF THE HEWLETT-PACKARD     * 
*  COMPANY.                                                     * 
*                                                               * 
***************************************************************** 
* 
*    NAME:  XPRTY 
*  SOURCE:  92067-18518 
*   RELOC:  PART OF 92067-12002 
*    PGMR:  J.S.W 
* 
* 
* CALLIN SEQUENCE:
*  CALL XPRTY(INTEGER)
*     WHERE INTEGER IS THE VALUE TO BE CONFIGURED 
*            PARITY BIT IS BIT 7, ONLY 7 BITS ARE COUNTED 
* 
* 
* 
XPRTY NOP 
      LDA XPRTY,I   GET RETURN ADDRESS
      STA RETN      SAVE,RETURN 
      ISZ XPRTY     STEP TO PARAMETER 1 
      LDA XPRTY,I   GET PARAMETER ADDRESS 
      STA .NUM      SAVE IT 
      LDA .NUM,I    GET ITS VALUE 
      LDB BM7       GET BIT COUNT (7 BITS)
      CCE           INDICATES ODD OR EVEN 
      SLA,RAR       IF EVEN SKIP
      CME           SET INDICATER 
      ISZ 1         PUMP COUNTER
      JMP *-3 
      LDA .NUM,I    GET OLD NUMBER
      SEZ 
      IOR BIT7      SET PARITY BIT IN BIT 7 
      STA .NUM,I
      JMP RETN,I    RETURN
* 
* 
BIT7  OCT 200 
.NUM  NOP 
RETN  NOP 
BM7   DEC -7
      END 
                                                                                                                                                                  