ASMB,R,L,C,Q
      HED LUSES 
*     NAME:   LUSES 
*     SOURCE: 92067-18481 
*     RELPC:  92067-16268 
*     PGMR:   G.L.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM LUSES,7 92067-1X481 REV.2013 790122 
* 
      ENT LUSES 
      EXT $SHED,$SMST,$SMLK 
* 
* 
* 
*  PURPOSE:  TO DETERMINE IF A SESSION CONTROL BLOCK EXISTS 
*            FOR A SPECIFIED SESSION TERMINAL.
* 
* 
* 
*  CALLING SEQUENCE:  JSB LUSES 
*                     DEF *+2 
*                     DEF LU
* 
* 
*  RETURNS:        (A)=0 IF SESSION CONTROL BLOCK NOT FOUND.
*                  (A)=ADDRESS OF SST LENGTH WORD OF REQUESTED
*                      SESSION CONTROL BLOCK IF FOUND.
* 
* 
*                  (B)= UNDEFINED 
      SPC 5 
LUSES NOP 
      ISZ LUSES     ADVANCE TO IDENTIFIER 
      LDA LUSES,I       AND FETCH IT'S ADDRESS
      ISZ LUSES     ADVANCE TO RETURN POINT 
      LDA A,I       FETCH AND 
      STA IDENT     SAVE IDENTIFIER 
* 
      LDA $SHED     FETCH HEAD OF SCB LIST
* 
*****FUTURE PTN TABLE WORK GOES HERE
*      --GO PRIV AND SET UP MAP 
* 
NEXT  SZA,RSS       END OF LIST?
      JMP LUSES,I   YES--RTN (A)=0
* 
      LDB A         MOVE SCB ADDR TO B
      LDA $SMST     FETCH OFFSET TO IDENT 
      ADA B         ADVANCE TO IT 
      XLA A,I          THEN FETCH IT
      AND B377          ISOLATE IT
      CPA IDENT     THIS THE ONE WERE LOOKING FOR ? 
      JMP MATCH     YES-- 
* 
      XLA B,I       NO-- FETCH NEXT SCB OR END
      JMP NEXT      CONTINUE SCAN 
* 
MATCH LDA $SMLK     GET NEG LENGTH TO LINK WORD(FROM SST LEN) 
      CMA,INA       SET IT POSITIVE 
      ADA B         MOVE SCB POINTER TO SST LENGTH WORD 
      JMP LUSES,I       AND RETURN
* 
IDENT NOP 
B377  OCT 377 
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                        