ASMB,Q,C
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
* 
* 
*     SOURCE PART NUMBER : 92067-18453
* 
*     RELOCATABLE PART NUMBER : 92067-16125 
* 
*     PROGRAMER(S)   : S.P.K.,J.M.N.
* 
* 
* IPRSN - ROUTINE TO MOVE USER.GROUP IN PACKED FORMAT IN
*         USER BUFFER 
*         CALLING SEQUENCE:  JSB IPRSN
*                            DEF *+4
*                            DEF NAME    11 WORD NAME OF USER AND GROUP 
*                            DEF BUF2    BUFFER TO MOVE USER.GROUP INTO 
*                            DEF PTR     CHAR OFFSET INTO BUFFER
* 
* 
      NAM IPRSN,7 92067-16125 REV.1903 790103   
      ENT IPRSN 
      EXT .ENTR,SETDB,ZPUT,CPUT 
NAME  NOP 
BUF2  NOP 
PTR   NOP 
* 
IPRSN NOP 
      JSB .ENTR 
      DEF NAME
      LDA PTR,I     GET CHAR POSITION IN BUFFER 
      ADA D21       MAX LENGTH OF USER.GROUP IS 21 CHARS
      STA TEMP3     SAVE THE END OF BUFFER ADDRESS
      JSB SETDB     SET DESTINATION BUFFER
      DEF *+3 
      DEF BUF2,I
      DEF PTR,I 
      LDA NAME,I    GET FIRST WORD OF SOURCE BUFFER 
      AND B377      GET # CHARS IN GROUP NAME 
      STA TEMP2     SAVE
      XOR NAME,I    GET # OF CHARS IN USER NAME 
      ALF,ALF 
      STA TEMP1 
      SZA,RSS 
      JMP IPRS1     IF NO USER PRINT GROUP ONLY 
      JSB ZPUT      MOVE THE STRING CONTAINING USER NAME
      DEF *+4 
      DEF NAME,I    SOURCE BUFFER 
      DEF D3        SOURCE POINTER
      DEF TEMP1     # OF CHARS
      JSB CPUT      INSERT A PERIOD BETWEEN USER, GROUP NAME
      DEF *+2 
      DEF "."       ". "
IPRS1 JSB ZPUT      MOVE GROUP NAME 
      DEF *+4 
      DEF NAME,I    SOURCE BUFFER 
      DEF D13       SOURCE POINTER
      DEF TEMP2     # OF CHARS
      LDA PTR,I     SAVE CURRENT POSITION OF DEST BUFFER POINTER
      STA TEMP2 
BLNKL CPA TEMP3     IS THIS POSITION SAME AS END OF USER.GROUP? 
      JMP DONE
      JSB CPUT      INSERT SPACE IN BUFFER
      DEF *+2 
      DEF DBLNK 
      LDA PTR,I 
      JMP BLNKL 
* 
DONE  LDA TEMP2     RETURN WITH POINTER TO END OF U.G 
      STA PTR,I 
      JMP IPRSN,I 
* 
"."   ASC 1,. 
D21   DEC 21
D3    DEC 3 
D13   DEC 13
TEMP3 NOP 
TEMP1 NOP 
TEMP2 NOP 
DBLNK ASC 1,
B377  OCT 377 
* 
* 
* 
* 
      END 
                                                                                                                                                                    