ASMB,R,L,C
      HED "SESSN" ROUTINE TO FIND IF IN SESSION MODE
*     NAME:   SESSN 
*     SOURCE: 92067-18451 
*     RELOC:  92067-16125 
*     PGMR:   B.L.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM SESSN,7 92067-16125 REV.1903 780413 
      ENT SESSN 
      EXT .ENTR     PARAMETER ADDRESS FETCH ROUTINE 
      SPC 1 
* 
* ROUTINE TO DETERMINE IF A PROGRAM IS IN SESSION MODE
* 
* CALLING SEQUENCE:   JSB SESSN 
*                     DEF *+2 
*                     DEF ID        ID SEG. ADDRESS OF PROGRAM
*                    <RETURN>       E=1 IF NOT IN SESSION MODE
*                                   E=0 IF IN SESSION MODE
*                                   B=ID SEGMENT SESSION WORD 
* 
* METHOD:  THIS ROUTINE EXAMINES ID SEGMENT WORD 33 (SESSION WORD). 
*          IF NEGATIVE OR ZERO, THE PROGRAM IS NOT IN SESSION,
*          OTHERWISE THE PROGRAM IS IN SESSION MODE.
* 
      SPC 1 
ID    NOP           ID SEGMENT ADDRESS OF PROGRAM 
SESSN NOP           ENTRY 
      JSB .ENTR     GET PARAMETER ADDRESS 
      DEF ID
      LDB ID,I      GET ID SEGMENT ADDRESS
      ADB .32       OFFSET TO ID SEGMENT SESSION WORD 
      XLB B,I       GET CONTENTS OF SESSION WORD
      CCE,SSB,RSS   POSITIVE? 
      SZB,RSS       ZERO? 
      RSS           WAS NEGATIVE OR ZERO, SO NON-SESSION
      CLE           IN SESSION, RETURN E=0
      JMP SESSN,I   RETURN
      SPC 1 
B     EQU 1 
.32   DEC 32
      END 
                                                                                                                                                                                                                  