ASMB,R,L
* 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
* 
*     SOURCE PART NUMBER :92067-18415 
* 
*     RELOCATABLE PART NUMBER : 92067-16361 
* 
*     PROGRAMER(S)   : J.M.N. 
* 
*  ***************************************************************
* 
      NAM ACITA,7 92067,16361 REV.1940 780801 
* 
* 
*     ACITA - INTEGER TO ASCII CONVERSION ROUTINE 
* 
*     CALLING SEQUENCE:  CALL ACITA(INT,IBUF,IWDS)
* 
*            CONVERTS AN INTEGER INT TO ITS DECIMAL EQUIVALENT
*            IN ASCII AND RETURNS IT IN THE ARRAY IBUF
*            (ARRAY LENGTH = IWDS)
* 
* 
      ENT ACITA 
      EXT .ENTR 
* 
A     EQU 0 
INT   BSS 1 
IBUF  BSS 1 
IWDS  BSS 1 
ACITA  NOP
      JSB .ENTR     GET PARAMETER ADDRESSES 
      DEF INT 
      LDA TA        SET UP NUMBER TABLE 
      STA IPICK       POINTER 
      LDA IWDS,I    GET LENGTH OF OUTPUT BUFFER 
      CPA .2        IF 2 WORDS LONG,
      JMP JUST2       BUMP NUMBER TABLE POINTER 
GTINT LDA INT,I     GET THE INTEGER 
      LDB MINUS     GENERATE THE SIGN 
      SSA             AND THE 
      CMA,INA,RSS       FIRST NUMBER
      LDB BLANK 
      JSB ONEN
      STB IBUF,I    SAVE IT 
      LDB IWDS,I    LENGTH OF OUTPUT BUFFER 
      CPB .2        IF ONLY 2 WORDS LONG, 
      JMP LAST      SKIP TO LAST WORD 
      CLB 
      JSB ONEN
      BLF,BLF 
      JSB ONEN
      ISZ IBUF
      STB IBUF,I
LAST  CLB 
      JSB ONEN
      BLF,BLF 
      ADB =B60
      ADB A 
      ISZ IBUF
      STB IBUF,I
      JMP ACITA,I 
      SPC 1 
JUST2 ISZ IPICK     BUMP NUMBER TABLE POINTER 
      ISZ IPICK 
      JMP GTINT     CONTINUE
      SPC 1 
ONEN  NOP           CONVERSION ROUTINE
      ADB =B60
ON1   ADA IPICK,I 
      SSA 
      JMP ON2 
      INB 
      JMP ON1 
ON2   CMA,INA 
      ADA IPICK,I 
      CMA,INA 
      ISZ IPICK 
      JMP ONEN,I    RETURN
      SPC 1 
TA    DEF NBUF
NBUF  DEC -10000
      DEC -1000 
      DEC -100
      DEC -10 
BLANK OCT 20000 
MINUS OCT 26400 
.2    DEC 2 
IPICK BSS 1 
      END 
                                                                                                                                                                                              