ASMB,Q,C
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
*     SOURCE PART NUMBER :92067-18393 
* 
*     RELOCATABLE PART NUMBER : 92067-16361 
* 
*     PROGRAMER(S)   : J.M.N. 
* 
* 
      NAM ACSBT,7 92067-16361 REV.1940 781212 
* 
*     ACSBT SETS ID IN BIT MAP
* 
*     CALLING SEQUENCE: 
*      CALL ACSBT(ID,NBUF)
*       WHERE: ID    IS THE ID # TO BE SET
*              NBUF  IS THE 256 WORD BUFFER CONTAINING
*                       THE ID BIT MAP
* 
      ENT ACSBT 
      EXT .ENTR 
* 
A     EQU 0 
B     EQU 1 
* 
ID    NOP           ID# 
NBUF  NOP           BUFFER ADDRESS OF BIT MAP 
ACSBT NOP 
      JSB .ENTR 
      DEF ID
* 
      LDB ID,I      FETCH ID #
      CLA 
      RRR 4         PUT WORD IN B REG 
      ALF           AND BIT IN A REG
      CMA           COMPUTE SHIFT COUNT 
      STA ID        (DON'T NEED THIS ADDRESS ANYMORE) 
      LDA SIGN      100000B 
LOOP  RAL           SHIFT THE ZERO TO THE RIGHT 
      ISZ ID        SPOT
      JMP LOOP
* 
      ADB NBUF      COMPUTE ADDRESS OF WORD 
      IOR B,I       THEN MERGE BIT
      STA B,I       AND RESTORE THE WORD
      JMP ACSBT,I   AND RETURN
* 
SIGN  OCT 100000
      END 
                                                                                                                                                                                                                        