ASMB,R,L,C    ** TRMLU - FIND 'LU' FROM EQT4 ADDR IN B REG ** 
      HED -TRMLU - FIND 'LU' FROM EQT4 ADDRESS IN B-REG 
*     NAME:   TRMLU 
*     SOURCE: 92067-18296 
*     RELOC:  PART OF 92067-16268 AND 92067-16035 
*     PGMR:   C.M.M.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM TRMLU,7 92067-1X296 REV.2013 771117 
      ENT TRMLU 
* 
*     ROUTINE TO FIND THE LOGICAL UNIT NUMBER OF A DEVICE 
*     GIVEN THE ADDRESS OF WORD 4 OF ITS EQUIPMENT TABLE
*          CALLED AS FOLLOWS: 
* 
*          LDB EQT4       (PASSED FROM DVR00/DVR65) 
* 
*          JSB TRMLU    -OR-    JSB TRMLU   -OR-   CALL TRMLU (LUSDI) 
*          DEF *+2             DEF *+1
*          DEF LUSDI
* 
*          A-REG. = 0   IF NOT FOUND -OR- 
*          A-REG. = THE LOGICAL UNIT NUMBER IF FOUND
*          LUSDI  = RETURNED SAME AS A-REG. 
*          B-REG. = ASCII "00" -OR- LOGICAL UNIT IN ASCII (I.E. "16") 
* 
      SUP 
TRMLU NOP        ENTRY
      STB EQT4     SAVE B-REG FOR LATER TEST
      LDA TRMLU,I   GET ADRS OF RETURN ADDRESS
      ISZ TRMLU     BUMP TO POSSIBLE PRAM.
      LDB TRMLU,I   GET POSS. ADDRS OF PRAM.
      CPA TRMLU     PARAMETER PASSED? 
      CLB          NO, SET DUMMY ADRS (A-REG.)
      STB LUADR    SET ADDRESS FOR PASSED PRAM
      STA TRMLU     SET UP RETURN ADDRESS 
      CLA           SET START LU = 0
      STA LUNUM 
* 
NEXT  LDA LUNUM    GET CURRENT LU NUM-1 
      CPA LUMAX    DONE THRU ALL LU'S 
      JMP NTFND    YES, NOT FOUND!! 
      ISZ LUNUM    BUMP TO CURRENT LU 
      ADA DRT      POINT TO TABLE ADDRESS 
      LDA 0,I      GET CONTENTS 
      AND O77      MASK OF SUBCHANNEL BITS
      MPY D15      CALCULATE ADDRESS OF WORD 4
      ADA EQTA     BASE ADDRESS 
      ADA DM12     SUBTRACK ONE EQT & ADD DEC 3 
      CPA EQT4     COMPARE??
      JMP FOUND    YES !! 
      JMP NEXT     NO, TRY NEXT ONE 
      SPC 1 
NTFND STB LUNUM    NOT FOUND RETURN A=0 
FOND1 LDA LUNUM    FOUND RETURN A= LU NUMBER
      DIV D10      CONVERT TO ASCII 
      ALF,ALF      POSITION MOST SIG. DIGIT 
      ADB 0        MIRGE IN LEAST 
      ADB ASC00    CONVERT TO ASCII 
      LDA LUNUM    RESTORE BINARY VALUE 
      STA LUADR,I  PASS BACK TO CALLER
      JMP TRMLU,I 
      SPC 1 
FOUND LDA EQT4      GET THE SPECIFIED LU
      INA           AND NOW EQT 5 
      LDA A,I 
      AND MEQT      GET THE TYPE
      SZA,RSS       DVR00 ? 
      JMP FOND1     YES, WERE DONE
      LDA DRT       MUST BE DVR05, SO GET DRT 
      ADA LUNUM     ADD LU #
      ADA DM1       DO OFFSET 
      LDA A,I       GET THE DRT VALUE 
      AND MSUB      GET THE SUB CHANNEL # 
      SZA,RSS       WAS IT THE CRT ?
      JMP FOND1     YES, SO DO IT.
      JMP NEXT
      SPC 1 
EQT4  NOP 
MSUB  OCT 174000
MEQT  OCT 37400 
DM1   DEC -1
LUADR NOP 
LUNUM NOP 
O77   OCT 77
D10   DEC 10
ASC00 ASC 1,00
D15   DEC 15
DM12  DEC -12 
EQTA  EQU 1650B 
DRT   EQU 1652B 
LUMAX EQU 1653B 
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                                                                                              