ASMB,R,L,C    ** IFTTY - SEE IF SPECIFIED LU IS INTERACTIVE.
      HED -IFTTY - DETERMINES IF SPECIFIED LU IS INTERACTIVE. 
*     NAME:   IFTTY 
*     SOURCE: 92067-18295 
*     RELOC:  PART OF 92067-16268 
*     PGMR:   C.M.M.,G.L.M. 
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM IFTTY,7 92067-1X295 REV.2013 790118 
      ENT IFTTY,.TTY,XFTTY
      EXT XLUEX 
* 
*     ROUTINE TO DETERMINE IF THE SPECIFIED LU IS INTERACTIVE 
*          CALLED AS FOLLOWS: 
* 
* IFLAG = IFTTY(LU)           JSB IFTTY 
*                             DEF *+2 
*                             DEF LU
* 
* 
* IFLAG = A REG = -1       IF THE LU IS INTERACTIVE 
*               =  0       IF THE LU IS NON-INTERACTIVE 
*         B REG = UPPER BYTE = DEVICE TYPE
*                 LOWER BYTE = SUBCHANNEL NUMBER
* 
* 
* 
.TTY  EQU * 
IFTTY NOP           ENTRY 
      DLD IFTTY,I   GET RETURN ADDRESS & LU#
      STA XFTTY     SAVE RETURN ADDRESS 
      LDA B,I       GET THE LU #
      AND B77       ISOLATE IT DOWN TO 6 BITS 
      JMP INT?
* 
* 
XFTTY NOP 
      DLD XFTTY,I 
      STA XFTTY 
      LDA B,I 
INT?  STA ANLU# 
      SZA,RSS       IF LU 0 
      JMP ITSNT      RETURN NOT-INTERACTIVE 
* 
* 
      JSB XLUEX     SEE IF THE LU IS INTERACTIVE
      DEF *+6 
      DEF D13I      STATUS REQUEST
      DEF ANLU#     THE LU WE WANT THE INFO ABOUT 
      DEF YTEMP     EQT WORD 5 PLACED HERE
      DEF DTYPE     EQT WORD 4 PLACED HERE(NOT NEEDED)
      DEF ZTEMP     SUB CHANNEL IN LOWER 5 BIT HERE 
* 
      JMP ITSNT     IT AIN'T EVEN AN LU !!!!
      LDA YTEMP     GET EQT WORD 5
      AND MEQT      KEEP ONLY THE EQT TYPE FIELD
      LDB A         AND SAVE IT 
      LDA ZTEMP     GET THE SUBCHANNEL BITS 
      AND M37 
      STA ZTEMP 
      ADA B        CONFIGURE B REGISTER RETURN WORD 
      STA DTYPE 
      SZB,RSS       IF DVR 00 THEN
      JMP ITSIN     ITS INTERACTIVE 
      CPB M2400     IF DVR 05 THEN
      JMP DVR05     DO ONE MORE CHECK FOR SUB CHANNEL 
      CPB M3400     IS IT DVR07 ? 
      JMP DVR05     THEN DO DVR05 CHECK 
      JMP ITSNT     ELSE ITS NOT INTERACTIVE
* 
DVR05 LDA ZTEMP     GET THE SUB CHANNEL # 
      SZA,RSS       IF  = 0 THEN ITS
ITSIN CCA,RSS       SET INTERACTIVE FLAG
ITSNT CLA           SET NON INTERACTIVE FLAG
      LDB DTYPE 
      JMP XFTTY,I   RETURN TO CALLER
* 
* 
D13I  OCT 100015
M2400 OCT 2400
M37   OCT 37
B77   OCT 77
M3400 OCT 3400
MEQT  OCT 37400 
ANLU# NOP 
DTYPE NOP 
YTEMP NOP 
ZTEMP NOP 
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                            