ASMB,L          ** .MVW - MOVE WORD ROUTINE **
*     NAME: .MVW
*     SOURCE: 92067-18288 
*     RELOC:  PART OF 92067-16268 AND 92067-16035 
*     PGMR:   G.A.A 
* 
      HED MOVE WORD ROUTINE TO SIMULATE 105777B MICROCODE INSTR 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1978.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
      NAM .MVW,7 92067-1X288 REV.2013 751021
      ENT .MVW
.MVW  EQU * 
*** 
MOVE  NOP 
      STA FROM      MICRO CODE MOVE REPLACEMENT SUB 
      LDA MOVE,I    GET THE COUNT 
      LDA A,I       TO A
      ISZ MOVE      STEP TO NOP (NOP IS RETURN) 
      SZA,RSS 
      JMP OUT       SKIP MOVE IF ZERO COUNT 
* 
      CMA,INA       SET IT NEGATIVE 
      STA COUNT     SET COUNTER 
LOOP  LDA FROM,I    GET WORD
      STA B,I       SET IN DESTINATION
      INB           STEP DESTINATION
      ISZ FROM      FROM
      ISZ COUNT     AND COUNT 
      JMP LOOP      IF NOT DONE LOOP
* 
OUT   LDA FROM      PUT NEXT LOCATION IN A FOR PURISTS
      JMP MOVE,I    AND RETURN
* 
* 
A     EQU 0 
B     EQU 1 
FROM  NOP 
COUNT NOP 
      END 
                                                                                                                            