ASMB,R,L,C    ** IFBRK ** 
      HED R/T IFBRK MODULE
*     NAME:   IFBRK 
*     SOURCE: 92067-18276 
*     RELOC:  PART OF 92067-16268 AND 92067-16035 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM IFBRK,7 92067-1X276 REV.2013 800129 
* 
      ENT IFBRK 
      EXT $LIBR,$LIBX 
      SPC 2 
*   CALLING SEQUENCE: 
* 
*     IF(IFBRK(IDMY)) 10,20 
* 
*   WHERE: 10  BRANCH WILL BE TAKEN IF SET & WILL CLEAR IT. 
*          20  BRANCH WILL BE TAKEN IF NOT SET
* 
*      JSB IFBRK
*      DEF *+1
*     <RETURN>   A-REG. = -1 IF SET, ELSE A-REG = 0 
*                BREAK BIT WILL ALWAYS BE CLEARED IF SET! 
      SPC 1 
IFBRK NOP          ENTRY FROM FTN 
      LDA IFBRK,I  GET P+1 ADDRESS
      STA IFBRK    SET RETURN ADDRESS 
      LDB XEQT     GET IDSEG ADDRESS OF THIS PROG 
      ADB D20      GET ID(21) ADDRESS 
      XLA B,I      GET CONTENTS 
      AND BIT12    MASK DOWN TO BIT 12
      SZA,RSS      SET? 
      JMP IFBRK,I  NO, RETURN A=0        *2013 DLS* 
      JSB $LIBR    YES, THEN TURN        *2013 DLS* 
      NOP           OFF INTERRUPTS       *2013 DLS* 
      XLA B,I        AND THEN CLEAR      *2013 DLS* 
      XOR BIT12       BIT 12 OF          *2013 DLS* 
      XSA B,I          WORD 21.          *2013 DLS* 
      CCA          RETURN A-REG. = -1 
      JSB $LIBX 
      DEF IFBRK 
* 
D20   DEC 20
BIT12 OCT 10000 
XEQT  EQU 1717B 
B     EQU 1 
      END 
                                                                                                                                                                                                                              