ASMB,R,L,C
*     NAME:   GTSCB 
*     SOURCE: 92067-18267 
*     RELOC:  92067-16125 
*     PGMR:   R.D.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM GTSCB,7 92067-16125 REV.1903 781016 
      ENT GTSCB 
      EXT SESSN,$SMLN,$SMVE,.ENTR,$SMLK,$SMST 
IBUFA NOP 
IBUFL NOP 
IERR  NOP 
ADSCB DEF ZERO
GTSCB NOP 
      JSB .ENTR     GET PARAMETERS
      DEF IBUFA 
* 
      CLB,CLE       CHECK WHETHER OR NOT IN SESSION 
      JSB SESSN 
      DEF *+2 
      DEF XEQT
      SEZ,RSS       ARE YOU IN SESSION? 
      JMP INSES     YES 
* 
      LDA ADSCB,I   ARE YOU PASSING SCB ADDR. 
      STA ADSCB 
      SZA           IF ZERO RETURN ERROR
      JMP SCBLT     GET SCB LENGTH
      LDA NEG1      RETURN IERR=-1
      STA IERR,I
      JMP FINSH 
INSES LDA ADSCB,I   ARE YOU IN SESS. AND PASSING DIFF. SCB ADDR?
      STA ADSCB 
      SZA,RSS       SKIP IF NOT USING CURRENT SCB ADDR. 
      STB ADSCB     OTHERWISE TAKE CURRENT SCB ADDR.
SCBLT JSB $SMVE     CALL TO GET SCB LENTGH
      DEF SMRTN 
      DEF DEC1       READ 
      DEF ADSCB     SCB ADDRESS 
      DEF $SMLN     OFFSET TO LENGTH WORD 
      DEF TMP1      PUT IT HERE 
      DEF DEC1      BUFFER LENGTH 
SMRTN EQU * 
* 
      LDA TMP1
      ADA NEG3
      STA IERR,I
* 
      LDA IERR,I    DETERMINE WHICH IS LESS 
      CMA,INA       IERR OR IBUFL 
      ADA IBUFL 
      SSA,RSS       IF SUM < 0 USE IBUFL
      STB TMP2
* 
* 
      LDA $SMLK 
      ADA $SMST 
      STA TMP2
* 
ERR   JSB $SMVE 
      DEF RTN 
      DEF DEC1      READ
      DEF ADSCB     FROM HERE 
      DEF TMP2      OFFSET FROM SESSION WORD
      DEF IBUFA,I   PUT IT HERE 
      DEF TMP1
RTN   EQU * 
FINSH LDA DEF.O 
      STA ADSCB 
      JMP GTSCB,I 
* 
A     EQU 0 
B     EQU 1 
ZERO  DEC 0 
DEF.O DEF ZERO
NEG3  DEC -3
TMP1  NOP 
TMP2  NOP 
XEQT  EQU 1717B 
NEG1  DEC -1
DEC1  DEC 1 
DEC3  DEC 3 
NOP   NOP 
      END 
                                                                                                                                                                                                                                            