ASMB,R,L
      HED AVAIL ROUTINE 
*     NAME:   AVAIL 
*     SOURCE: 92067-18174 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM AVAIL,8 92067-16125 REV.1903 741231 
      ENT AVAIL,.LUAV 
* 
      EXT .ENTR,$LUAV 
* 
ADDR  NOP 
MASK  NOP 
FNUM  NOP 
* 
AVAIL NOP 
      JSB .ENTR 
      DEF ADDR
      LDA M5
      STA SAVE1 
      CLA,INA 
      STA FNUM,I
LOOP1 LDB M16 
      STB SAVE2 
LOOP2 STA MASK,I
      AND ADDR,I
      SZA,RSS 
      JMP HAVIT 
      ISZ FNUM,I
      LDA MASK,I
      RAL 
      ISZ SAVE2 
      JMP LOOP2 
      ISZ ADDR
      ISZ SAVE1 
      JMP LOOP1 
      CLA 
      STA FNUM,I
      JMP AVAIL,I 
HAVIT LDA MASK,I
      IOR ADDR,I
      STA ADDR,I
      JMP AVAIL,I 
* 
SAVE1 BSS 1 
SAVE2 BSS 1 
M5    DEC -5
M16   DEC -16 
D2    DEC 2 
DLUAV DEF $LUAV 
* 
.LUAV NOP 
      LDA $LUAV     GET THE TABLE COUNT 
      SZA,RSS       IF ZERO,
      JMP EX        JUST EXIT 
* 
      STA SAVE1     SET THE COUNTER 
      LDA .LUAV,I   GET THE PRAM ADDRESS
      STA AVAIL     AND SAVE IT 
      LDB DLUAV     GET THE TABLE ADDRESS 
      RBL,CLE,SLB,ERB MAKE DIRECT 
      LDB B,I       GET ADDRESS 
      INB           STEP TO FIRST WORD
AVLOP LDA B,I       GET THE ENTRY 
      AND B77 
      CPA AVAIL,I   HERE? 
      JMP EX        YES GO EXIT 
* 
      ADB D2        NO STEP TO NEXT ENTRY 
      ISZ SAVE1     IS THERE ONE? 
      JMP AVLOP     YES GO TRY IT 
* 
      CLA           MAKE OK EXIT
EX    ISZ .LUAV     STEP TO RETURN ADDRESS
      JMP .LUAV,I   AND RETURN
* 
B77   OCT 77
A     EQU 0 
B     EQU 1 
      END 
                                                                                                                                                                                                                                                