ASMB,R,L
      HED LU.CL ROUTINE 
*     NAME:   LU.CL 
*     SOURCE: 92067-18173 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM LU.CL,8 92067-16125 REV.1903 780915 
      ENT LU.CL 
* 
      EXT LULU.,.ENTR,$LUSW,.DRCT,EXEC,S.CAP
* 
*     CHANGE RECORD 
* 
*     780915 CHANGED TO DO NOTHING IF IN SESSION  (GAA) 
* 
* 
*  THE FOLLOWING ROUTINE GOES THROUGH THE $LUSW 
*  TABLE AND CLOSES ALL SPOOL LU'S. 
* 
* 
LU.CL NOP 
      JSB .ENTR 
      DEF LU.CL 
      LDA S.CAP     GET THE SESSION FLAG
      SZA           IF IN SESSION 
      JMP LU.CL,I   JUST RETURN 
* 
      JSB .DRCT 
      DEF $LUSW 
      STA ADDR
      LDB 0,I 
      CMB,INB 
      STB CNTR
LOOP2 ISZ ADDR
      LDA ADDR,I
      SSA 
      JMP LOOP1 
* 
      ALF,ALF       GET THE DIRECT LU 
      AND B77 
      INA 
      STA LUNO
      JSB EXEC
      DEF *+5 
      DEF D23 
      DEF SMPA
      DEF D4
      DEF LUNO
LOOP1 ISZ CNTR
      JMP LOOP2 
* 
      JSB LULU.     ALL CLOSED NOW CLEAR THE TABLE
      DEF *+2 
      DEF ZERO
ZERO  NOP           IGNOR ERROR RETURN
      JMP LU.CL,I   RETURN
* 
D4    DEC 4 
D23   DEC 23
B77   OCT 77
ADDR  BSS 1 
CNTR  BSS 1 
LUNO  BSS 1 
SMPA  ASC 3,SMP 
* 
      END 
                                                                                                              