ASMB,R,L
      HED EX.TM ROUTINE 
*     NAME:   EX.TM 
*     SOURCE: 92067-18171 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM EX.TM,8 92067-16125 REV.1903 771115 
      ENT EX.TM 
* 
      EXT $BATM,TM.VL,CONV.,IPUT,.DRCT
      EXT EXEC,FIT.,.ENTR,WRITF,O.BUF 
      EXT FM.ER 
      SUP 
A     EQU 0 
XEQT  EQU 1717B 
* 
*  THE FOLLOWING ROUTINE PRINT OUT TOTAL
*  EXECUTION TIME FOR THE CURRENT JOB.
* 
EX.TM NOP 
      JSB .ENTR 
      DEF EX.TM 
      DLD TM.VL 
      CMA,CLE,INA 
      CMB,SEZ 
      INB 
      DST SAVE1 
      DLD $BATM 
      CLE 
      ADA SAVE1 
      SEZ 
      INB 
      ADB SAVE2 
      DST SAVE1 
      CLA 
      STA SAVE3 
      JSB .DRCT 
      DEF $BATM 
      STA HSEC
      INA 
      STA SEC 
**
* 
      LDA XEQT       CHECK TO SEE IF BATCH FLAG SET 
      ADA D20 
      LDA A,I 
      ELA           BATCH FLAG SET??
      SEZ,RSS 
      JMP NOBTH     NOT SET SO DON'T TOUCH THE BATCH TIMER
* 
      JSB IPUT       GO CLEAR THE FIRST WORD
      DEF *+3 
      DEF HSEC
      DEF SAVE3 
      JSB IPUT       AND NOW THE SECOND WORD
      DEF *+3 
      DEF SEC 
      DEF SAVE3 
**
* 
NOBTH DLD SAVE1 
* 
      DIV D6000 
      STB SAVE3 
      CLB 
      DIV D60 
      STA SAVE1     HOURS 
      STB SAVE2     MINUTES 
      LDA SAVE3 
      CLB 
      DIV D100
      STA SEC       SECONDS 
      STB HSEC      HUNDREDTHS OF SECONDS 
      JSB CONV.     CONVERT AND STORE HOURS.
      DEF *+4 
      DEF SAVE1 
      DEF EXMS1 
      DEF D2
      JSB CONV.     CONVERT AND STORE MINUTES.
      DEF *+4 
      DEF SAVE2 
      DEF SAVE1 
      DEF D2
      JSB .DRCT 
      DEF EXMS1+1 
      LDB SAVE1 
      JSB FIT.
      JSB CONV.     CONVERT AND STORE SECONDS.
      DEF *+4 
      DEF SEC 
      DEF EXMS2+1 
      DEF D2
      JSB CONV.     CONVERT HUNDREDTHS OF SECONDS.
      DEF *+4 
      DEF HSEC
      DEF SAVE1 
      DEF D2
      JSB .DRCT 
      DEF EXMS2+2 
      LDB SAVE1 
      JSB FIT.
      JSB WRITF 
      DEF *+5 
      DEF O.BUF 
      DEF SAVE1 
      DEF EXMS+1
      DEF EXMS
      JSB WRITF     NOW DO TOP OF 
      DEF *+5       FORM TO FINISH
      DEF O.BUF     THE JOB 
      DEF SAVE1 
      DEF EXMS+1
      DEF N1
      LDA SAVE1     IF ERROR ON LIST FILE 
      SSA,RSS       THEN
      JMP EX.TM,I 
* 
      JSB FM.ER     REPORT TO OPERATOR
      DEF EX
      DEF D2
      DEF LISTO 
      DEF D7
EX    JMP EX.TM,I 
* 
EXMS  DEC 15
      ASC 9, EXECUTION TIME:
EXMS1 BSS 1 
      ASC 1,: 
EXMS2 ASC 1, :
      BSS 1 
      ASC 1,. 
      ASC 1,
* 
N1    DEC -1
D1    DEC 1 
D2    EQU * 
WRITE DEC 2 
ICNW  OCT 6 
SAVE1 BSS 1 
SAVE2 BSS 1 
SAVE3 BSS 1 
HSEC  BSS 1 
SEC   BSS 1 
D6000 DEC 6000
D100  DEC 100 
D60   DEC 60
D20   DEC 20
* 
D7    DEC 7 
LISTO ASC 7,LIST OVERFLOW!
      END 
                                                                                                                                                                                                                                          