ASMB,R,L
      HED LULU ROUTINE
*     NAME:   LULU. 
*     SOURCE: 92067-18168 
*     RELOC:  92067-16125 
*     PGMR:   A.M.G.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM LULU.,6 92067-16125 REV.1903 780915 
      ENT LULU. 
* 
      EXT .ENTP,$LUSW,$LIBR,$LIBX,.DRCT,S.CAP 
* 
*     CHANGE RECORD:
* 
*     780915  TO DO NOTHING IF FMGR IS IN SESSION MODE (GAA)
* 
*  THE FOLLOWING ROUTINE MANIPULATES THE
*  BATCH LU TRANSFORM TABLE.
* 
LU1   BSS 1 
LU2   BSS 1 
* 
LULU. NOP 
      JSB $LIBR 
      NOP 
      JSB .ENTP 
      DEF LU1 
      LDA S.CAP     GET THE SESSION CAPABILITY FLAG 
      SZA           IF ZERO THEN NOT IN SESSION 
      JMP OKOUT     IN SESSION TAKE NORMAL RETURN 
* 
      STA ADDR
      JSB .DRCT 
      DEF $LUSW 
      STA 1 
      LDA 1,I       GET SIZE OF TABLE 
      CMA,INA       AND FORM COUNTER. 
      STA CNTR
      INB 
      LDA LU1,I 
      SZA,RSS       IS LU1 ZERO?
      JMP RESET     YES.  GO RESET THE TABLE. 
LOOP1 LDA 1,I       SEARCH THE TABLE FOR (LU1-1). 
      SSA           KEEP TRACK OF EMPTY ENTRIES.
      STB ADDR      SAVE ADDRESS OF EMPTY ENTRY.
      AND B377
      INA 
      CPA LU1,I 
      JMP GOTIT     HAVE IT.
      INB 
      ISZ CNTR
      JMP LOOP1 
      LDB ADDR      DO WE HAVE AN EMPTY ENTRY?
      SZB,RSS 
      JMP OUT       NO.  NO ROOM. 
GOTIT LDA LU2,I     WAS THIS A CLEAR REQUEST? 
      CPA CLR       IF THE CLEAR CODE '- '
      CCA,RSS       THEN SET TO -1 AND SKIP 
      JMP SET       NO. 
      JMP DEP 
* 
SET   LDA LU1,I 
      ADA M1
      ALF,ALF       PUT THE NEW LU TRANSFORM
      XOR LU2,I     INTO THE TABLE. 
      ADA M1
      ALF,ALF 
DEP   STA 1,I 
OKOUT ISZ LULU. 
OUT   JSB $LIBX 
      DEF LULU. 
RESET CCA           RESET LU TABLE TO STANDARD
      STA 1,I       DEVICES BY CLEARING THE ENTRIES.
      INB 
      ISZ CNTR
      JMP RESET 
      JMP OUT-1 
* 
B377  OCT 377 
ADDR  BSS 1 
CNTR  BSS 1 
M1    DEC -1
CLR   ASC 1,- 
* 
      END 
                                                                                                                                                