ASMB,R,L
      HED B.FLG ROUTINE 
*     NAME:   B.FLG 
*     SOURCE: 92067-18167 
*     RELOC:  92067-16125 
*     PGMR:   G.A.A.
* 
*  ***************************************************************
*  * (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979.  ALL RIGHTS     *
*  * RESERVED.  NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED,      *
*  * REPRODUCED OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT*
*  * THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY.       *
*  ***************************************************************
* 
      NAM B.FLG,8 92067-16125 REV.1903 741118 
      ENT B.FLG 
* 
      EXT $LIBR,$LIBX,.ENTP 
* 
PARAM NOP 
* 
B.FLG NOP 
      JSB $LIBR 
      NOP 
      JSB .ENTP 
      DEF PARAM 
      LDB XEQT      IF NOT FMGR 
      ADB D12       THEN DO NOT SET 
      LDA B,I       THE FLAG
      CPA "FM"      FIRST WORD CHECK
      INB,RSS       OK SKIP 
      JMP EX        BAD NEWS
* 
      LDA B,I       GET NEXT WORD 
      CPA "GR"      OK? 
      INB,RSS       YES SKIP
      JMP EX        NO EXIT 
* 
      LDA B,I       GET LAST WORD 
      AND C377      MASK TO HIGH ONLY 
      CPA BL        MAKE IT?
      RSS           YES SKIP
      JMP EX        NO EXIT 
* 
      LDB PARAM,I 
      LDA XEQT
      ADA D20 
      STA PARAM 
      LDA PARAM,I 
      IOR MASK
      SZB,RSS 
      XOR MASK
      STA PARAM,I 
EX    JSB $LIBX 
      DEF B.FLG 
* 
MASK  OCT 100000
D12   DEC 12
C377  OCT 177400
"FM"  ASC 1,FM
"GR"  ASC 1,GR
BL    OCT 20000 
A     EQU 0 
B     EQU 1 
D20   DEC 20
XEQT  EQU 1717B 
* 
      END 
                                                                                                                                                                        